mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-04 04:57:07 -08:00
Agostino Sarubbo
19fe41e40c
Package-Manager: Portage-3.0.9, Repoman-3.0.2 RepoMan-Options: --include-arches="amd64" Signed-off-by: Agostino Sarubbo <ago@gentoo.org>
51 lines
1.1 KiB
Bash
51 lines
1.1 KiB
Bash
# Copyright 1999-2021 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=7
|
|
|
|
PYTHON_COMPAT=( pypy3 python3_{6..9} )
|
|
|
|
inherit distutils-r1
|
|
|
|
MY_PN="SecretStorage"
|
|
|
|
DESCRIPTION="Python bindings to FreeDesktop.org Secret Service API."
|
|
HOMEPAGE="https://github.com/mitya57/secretstorage https://pypi.org/project/SecretStorage/"
|
|
SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
|
|
S="${WORKDIR}/${MY_PN}-${PV}"
|
|
|
|
LICENSE="BSD"
|
|
SLOT="0"
|
|
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~ppc ppc64 sparc ~x86 ~amd64-linux ~x86-linux"
|
|
|
|
RDEPEND="
|
|
dev-python/cryptography[${PYTHON_USEDEP}]
|
|
>=dev-python/jeepney-0.6[${PYTHON_USEDEP}]
|
|
"
|
|
BDEPEND="
|
|
test? ( !hppa? ( !sparc? (
|
|
gnome-base/gnome-keyring
|
|
sys-apps/dbus
|
|
) ) )
|
|
"
|
|
|
|
distutils_enable_tests unittest
|
|
distutils_enable_sphinx docs \
|
|
dev-python/alabaster
|
|
|
|
src_test() {
|
|
case ${ARCH} in
|
|
hppa|sparc)
|
|
einfo "gnome-keyring is not supported on ${ARCH}, skipping tests"
|
|
return
|
|
;;
|
|
esac
|
|
|
|
distutils-r1_src_test
|
|
}
|
|
|
|
python_test() {
|
|
dbus-run-session "${EPYTHON}" -m unittest discover -v -s tests \
|
|
|| die "tests failed with ${EPYTHON}"
|
|
}
|