mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2025-12-21 21:17:37 -08:00
0ad96e879b
Result of running the command: grep --include="*.ebuild" -r . -e 'KEYWORDS=.*[" ]sparc' -l | xargs ekeyword ~sparc Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>
51 lines
1.1 KiB
Bash
51 lines
1.1 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
inherit autotools
|
|
|
|
DESCRIPTION="A file archival tool which can also read and write tar files"
|
|
HOMEPAGE="https://www.gnu.org/software/cpio/cpio.html"
|
|
SRC_URI="mirror://gnu/cpio/${P}.tar.bz2"
|
|
|
|
LICENSE="GPL-3+"
|
|
SLOT="0"
|
|
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
|
|
IUSE="nls"
|
|
|
|
PDEPEND="
|
|
app-alternatives/cpio
|
|
"
|
|
|
|
PATCHES=(
|
|
"${FILESDIR}"/${PN}-2.12-non-gnu-compilers.patch #275295
|
|
"${FILESDIR}"/${PN}-2.14-sysmacros-glibc-2.26.patch
|
|
)
|
|
|
|
src_prepare() {
|
|
default
|
|
|
|
eautoreconf
|
|
}
|
|
|
|
src_configure() {
|
|
local myeconfargs=(
|
|
$(use_enable nls)
|
|
--bindir="${EPREFIX}"/bin
|
|
--with-rmt="${EPREFIX}"/usr/sbin/rmt
|
|
# install as gcpio for better compatibility with non-GNU userland
|
|
--program-prefix=g
|
|
)
|
|
|
|
econf "${myeconfargs[@]}"
|
|
}
|
|
|
|
pkg_postinst() {
|
|
# ensure to preserve the symlink before app-alternatives/cpio
|
|
# is installed
|
|
if [[ ! -h ${EROOT}/bin/cpio ]]; then
|
|
ln -s gcpio "${EROOT}/bin/cpio" || die
|
|
fi
|
|
}
|