mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-01-06 02:17:34 -08:00
72 lines
1.8 KiB
Bash
72 lines
1.8 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
ECM_HANDBOOK="optional"
|
|
ECM_TEST="forceoptional"
|
|
PVCUT=$(ver_cut 1-3)
|
|
KFMIN=6.19.0
|
|
QTMIN=6.9.1
|
|
inherit ecm gear.kde.org xdg
|
|
|
|
DESCRIPTION="Advanced download manager by KDE"
|
|
HOMEPAGE="https://apps.kde.org/kget/"
|
|
|
|
LICENSE="GPL-2" # TODO: CHECK
|
|
SLOT="6"
|
|
KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
|
|
IUSE="bittorrent gpg mms sqlite"
|
|
|
|
RDEPEND="
|
|
>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,sql,widgets,xml]
|
|
>=kde-frameworks/kcmutils-${KFMIN}:6
|
|
>=kde-frameworks/kcompletion-${KFMIN}:6
|
|
>=kde-frameworks/kconfig-${KFMIN}:6
|
|
>=kde-frameworks/kconfigwidgets-${KFMIN}:6
|
|
>=kde-frameworks/kcoreaddons-${KFMIN}:6
|
|
>=kde-frameworks/kcrash-${KFMIN}:6
|
|
>=kde-frameworks/kdbusaddons-${KFMIN}:6
|
|
>=kde-frameworks/ki18n-${KFMIN}:6
|
|
>=kde-frameworks/kiconthemes-${KFMIN}:6
|
|
>=kde-frameworks/kio-${KFMIN}:6
|
|
>=kde-frameworks/kitemviews-${KFMIN}:6
|
|
>=kde-frameworks/knotifications-${KFMIN}:6
|
|
>=kde-frameworks/knotifyconfig-${KFMIN}:6
|
|
>=kde-frameworks/kstatusnotifieritem-${KFMIN}:6
|
|
>=kde-frameworks/kwallet-${KFMIN}:6
|
|
>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
|
|
>=kde-frameworks/kwindowsystem-${KFMIN}:6
|
|
>=kde-frameworks/kxmlgui-${KFMIN}:6
|
|
bittorrent? ( >=net-libs/libktorrent-${PVCUT}:6 )
|
|
gpg? (
|
|
dev-cpp/gpgmepp:=
|
|
dev-libs/qgpgme:=
|
|
)
|
|
mms? ( media-libs/libmms )
|
|
sqlite? ( dev-db/sqlite:3 )
|
|
"
|
|
DEPEND="${RDEPEND}"
|
|
|
|
src_configure() {
|
|
local mycmakeargs=(
|
|
$(cmake_use_find_package bittorrent KTorrent6)
|
|
$(cmake_use_find_package gpg Gpgmepp)
|
|
$(cmake_use_find_package gpg QGpgmeQt6)
|
|
$(cmake_use_find_package mms LibMms)
|
|
$(cmake_use_find_package sqlite SQLite3)
|
|
)
|
|
|
|
ecm_src_configure
|
|
}
|
|
|
|
src_test() {
|
|
# bug 756817: schedulertest fails, see also upstream commit 45735cfa
|
|
# filedeletertest hangs.
|
|
local myctestargs=(
|
|
-E "(schedulertest|filedeletertest)"
|
|
)
|
|
|
|
ecm_src_test
|
|
}
|