mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-24 06:48:18 -07:00
064af661d0
The result was achieved via the following pipeline:
pkgcheck scan -c RestrictTestCheck -R FormatReporter \
--format '{category}/{package}/{package}-{version}.ebuild' |
xargs -n32 grep -L RESTRICT |
xargs -n32 sed -i -e '/^IUSE=.*test/aRESTRICT="!test? ( test )"'
The resulting metadata was compared before and after the change.
Few Go ebuilds had to be fixed manually due to implicit RESTRICT=strip
added by the eclass. Two ebuilds have to be fixed because of multiline
IUSE.
Suggested-by: Robin H. Johnson <robbat2@gentoo.org>
Closes: https://github.com/gentoo/gentoo/pull/13942
Signed-off-by: Michał Górny <mgorny@gentoo.org>
54 lines
1.3 KiB
Bash
54 lines
1.3 KiB
Bash
# Copyright 1999-2019 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=7
|
|
PYTHON_COMPAT=( pypy{,3} python{2_7,3_{5,6,7}} )
|
|
|
|
inherit distutils-r1
|
|
|
|
MY_COMMIT="9eac2dcc9b81c3af29c2386ce1afba9b446562bf"
|
|
|
|
DESCRIPTION="Infrastructure for theming support in Flask applications"
|
|
HOMEPAGE="https://pythonhosted.org/Flask-Themes/"
|
|
# https://github.com/maxcountryman/flask-themes/issues/8
|
|
SRC_URI="https://github.com/maxcountryman/${PN}/archive/${MY_COMMIT}.tar.gz -> ${P}.tar.gz"
|
|
|
|
LICENSE="MIT"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64 ~x86"
|
|
IUSE="doc test"
|
|
RESTRICT="!test? ( test )"
|
|
|
|
RDEPEND="
|
|
>=dev-python/flask-0.6[${PYTHON_USEDEP}]
|
|
dev-python/six[${PYTHON_USEDEP}]
|
|
"
|
|
# No need to depend on dev-python/flask-sphinx-themes,
|
|
# it is bundled in docs/_themes
|
|
BDEPEND="
|
|
dev-python/setuptools[${PYTHON_USEDEP}]
|
|
doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
|
|
test? (
|
|
${RDEPEND}
|
|
dev-python/nose[${PYTHON_USEDEP}]
|
|
)
|
|
"
|
|
|
|
S="${WORKDIR}/${PN}-${MY_COMMIT}"
|
|
|
|
python_prepare_all() {
|
|
sed -i "s/, 'sphinx.ext.intersphinx'//" docs/conf.py || die
|
|
distutils-r1_python_prepare_all
|
|
}
|
|
|
|
python_compile_all() {
|
|
if use doc; then
|
|
sphinx-build docs docs/_build/html || die
|
|
HTML_DOCS=( docs/_build/html/. )
|
|
fi
|
|
}
|
|
|
|
python_test() {
|
|
nosetests -v || die "Tests failed under ${EPYTHON}"
|
|
}
|