mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2025-12-23 21:57:33 -08:00
d83e25b6a5
sed -E '/dev-libs\/gobject-introspection(:=|\s|$|-[0-9]|\[)/ { s/(>=)?dev-libs\/gobject-introspection(-[0-9.r-]*)?/>=dev-libs\/gobject-introspection-1.82.0-r2/ }' */*/*.ebuild -i
+ manually going over to undo the false positives or if the version
requirement was higher.
Bug: https://bugs.gentoo.org/947058
See-Also: ae37e3f389808700bd0f4343ee04888f0ef179d2
Signed-off-by: Alfred Wingate <parona@protonmail.com>
Part-of: https://github.com/gentoo/gentoo/pull/44336
Closes: https://github.com/gentoo/gentoo/pull/44336
Signed-off-by: Sam James <sam@gentoo.org>
73 lines
1.8 KiB
Bash
73 lines
1.8 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
inherit gnome.org meson-multilib vala xdg
|
|
|
|
DESCRIPTION="GObject-based API for handling resource discovery and announcement over SSDP"
|
|
HOMEPAGE="https://wiki.gnome.org/Projects/GUPnP https://gitlab.gnome.org/GNOME/gssdp"
|
|
|
|
LICENSE="LGPL-2+"
|
|
SLOT="0/1.2-0" # <API version>-<soname>
|
|
KEYWORDS="~alpha amd64 ~arm arm64 ~hppa ~loong ~ppc ppc64 ~riscv ~sparc x86"
|
|
IUSE="gtk-doc +introspection gtk vala"
|
|
REQUIRED_USE="vala? ( introspection )"
|
|
|
|
RDEPEND="
|
|
!<net-libs/gssdp-1.6.4:1.6
|
|
>=dev-libs/glib-2.54:2[${MULTILIB_USEDEP}]
|
|
>=net-libs/libsoup-2.26.1:2.4[${MULTILIB_USEDEP},introspection?]
|
|
gtk? ( gui-libs/gtk:4 )
|
|
introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2:= )
|
|
"
|
|
DEPEND="${RDEPEND}"
|
|
BDEPEND="
|
|
gtk-doc? (
|
|
>=dev-util/gi-docgen-2021.1
|
|
app-text/docbook-xml-dtd:4.1.2
|
|
)
|
|
virtual/pkgconfig
|
|
vala? (
|
|
$(vala_depend)
|
|
net-libs/libsoup:2.4[vala]
|
|
)
|
|
"
|
|
PATCHES=(
|
|
"${FILESDIR}"/${P}-client-crash.patch
|
|
)
|
|
|
|
src_prepare() {
|
|
default
|
|
use vala && vala_setup
|
|
}
|
|
|
|
multilib_src_configure() {
|
|
local emesonargs=(
|
|
# Never use gi-docgen subproject
|
|
--wrap-mode nofallback
|
|
|
|
$(meson_native_use_bool gtk-doc gtk_doc)
|
|
$(meson_native_use_bool gtk sniffer)
|
|
$(meson_native_use_bool introspection)
|
|
$(meson_native_use_bool vala vapi)
|
|
-Dexamples=false
|
|
)
|
|
meson_src_configure
|
|
}
|
|
|
|
multilib_src_install_all() {
|
|
if use gtk-doc ; then
|
|
mv "${ED}"/usr/share/doc/{gssdp-1.2,${PF}} || die
|
|
mv "${ED}"/usr/share/doc/${PF}/{reference,html} || die
|
|
rmdir "${ED}"/usr/share/doc/gssdp-1.2
|
|
fi
|
|
|
|
# has file collision with slot 1.6 (/usr/bin/gssdp-device-sniffer),
|
|
# so we rename it in this build
|
|
if use gtk; then
|
|
mv "${ED}"/usr/bin/gssdp-device-sniffer \
|
|
"${ED}"/usr/bin/gssdp-device-sniffer-1.4 || die
|
|
fi
|
|
}
|