mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-24 18:58:08 -07:00
d83e25b6a5
sed -E '/dev-libs\/gobject-introspection(:=|\s|$|-[0-9]|\[)/ { s/(>=)?dev-libs\/gobject-introspection(-[0-9.r-]*)?/>=dev-libs\/gobject-introspection-1.82.0-r2/ }' */*/*.ebuild -i
+ manually going over to undo the false positives or if the version
requirement was higher.
Bug: https://bugs.gentoo.org/947058
See-Also: ae37e3f389
Signed-off-by: Alfred Wingate <parona@protonmail.com>
Part-of: https://github.com/gentoo/gentoo/pull/44336
Closes: https://github.com/gentoo/gentoo/pull/44336
Signed-off-by: Sam James <sam@gentoo.org>
66 lines
1.3 KiB
Bash
66 lines
1.3 KiB
Bash
# Copyright 2022-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
PYTHON_COMPAT=( python3_{11..14} )
|
|
inherit gnome.org meson python-any-r1 vala virtualx xdg
|
|
|
|
DESCRIPTION="Building blocks for modern GNOME applications"
|
|
HOMEPAGE="https://gnome.pages.gitlab.gnome.org/libadwaita/ https://gitlab.gnome.org/GNOME/libadwaita"
|
|
|
|
LICENSE="LGPL-2.1+"
|
|
SLOT="1"
|
|
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
|
|
|
|
IUSE="+introspection test +vala"
|
|
REQUIRED_USE="vala? ( introspection )"
|
|
|
|
RDEPEND="
|
|
>=dev-libs/glib-2.76:2
|
|
>=gui-libs/gtk-4.15.2:4[introspection?]
|
|
dev-libs/appstream:=
|
|
dev-libs/fribidi
|
|
introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2:= )
|
|
"
|
|
DEPEND="${RDEPEND}
|
|
x11-base/xorg-proto"
|
|
BDEPEND="
|
|
${PYTHON_DEPS}
|
|
vala? ( $(vala_depend) )
|
|
dev-util/glib-utils
|
|
sys-devel/gettext
|
|
virtual/pkgconfig
|
|
dev-lang/sassc
|
|
"
|
|
|
|
src_prepare() {
|
|
default
|
|
use vala && vala_setup
|
|
xdg_environment_reset
|
|
}
|
|
|
|
src_configure() {
|
|
local emesonargs=(
|
|
# Never use gi-docgen subproject
|
|
--wrap-mode nofallback
|
|
|
|
-Dprofiling=false
|
|
$(meson_feature introspection)
|
|
$(meson_use vala vapi)
|
|
-Dgtk_doc=false
|
|
$(meson_use test tests)
|
|
-Dexamples=false
|
|
)
|
|
meson_src_configure
|
|
}
|
|
|
|
src_test() {
|
|
addwrite /dev/dri
|
|
virtx meson_src_test --timeout-multiplier 2
|
|
}
|
|
|
|
src_install() {
|
|
meson_src_install
|
|
}
|