mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-02-16 03:47:28 -08:00
098de38294
Signed-off-by: Aaron Bauman <bman@gentoo.org> Package-Manager: Portage-2.3.80, Repoman-2.3.19
62 lines
1.6 KiB
Bash
62 lines
1.6 KiB
Bash
# Copyright 1999-2019 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=7
|
|
|
|
PYTHON_COMPAT=( python{2_7,3_{5,6,7,8}} pypy{,3} )
|
|
|
|
inherit distutils-r1
|
|
|
|
DESCRIPTION="Extensions to the standard Python datetime module"
|
|
HOMEPAGE="
|
|
https://dateutil.readthedocs.org/
|
|
https://pypi.org/project/python-dateutil
|
|
https://github.com/dateutil/dateutil/
|
|
"
|
|
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
|
|
|
|
LICENSE="BSD"
|
|
SLOT="0"
|
|
KEYWORDS="~alpha ~amd64 ~arm arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
|
|
IUSE="test"
|
|
|
|
RDEPEND="
|
|
>=dev-python/six-1.5[${PYTHON_USEDEP}]
|
|
sys-libs/timezone-data
|
|
"
|
|
BDEPEND="${RDEPEND}
|
|
dev-python/setuptools[${PYTHON_USEDEP}]
|
|
test? (
|
|
dev-python/freezegun[${PYTHON_USEDEP}]
|
|
dev-python/hypothesis[${PYTHON_USEDEP}]
|
|
)
|
|
"
|
|
|
|
RESTRICT="!test? ( test )"
|
|
|
|
PATCHES=(
|
|
"${FILESDIR}/0001-zoneinfo-Get-timezone-data-from-system-tzdata-r1.patch"
|
|
"${FILESDIR}/python-dateutil-2.8.1-no-pytest-cov.patch"
|
|
)
|
|
|
|
distutils_enable_tests pytest
|
|
|
|
python_prepare_all() {
|
|
# avoid a setuptools_scm dependency
|
|
sed -i "s:use_scm_version=True:version='${PV}',name='${PN//-/.}':" setup.py || die
|
|
sed -r -i "s:setuptools_scm[[:space:]]*([><=]{1,2}[[:space:]]*[0-9.a-zA-Z]+|)[[:space:]]*::" \
|
|
setup.cfg || die
|
|
|
|
# don't install zoneinfo tarball
|
|
sed -i '/package_data=/d' setup.py || die
|
|
|
|
distutils-r1_python_prepare_all
|
|
}
|
|
|
|
python_prepare() {
|
|
if [[ ${EPYTHON} == python3.7 ]]; then
|
|
# these tests are flakey on 3.7
|
|
rm dateutil/test/property/test_{parser,isoparse}_prop.py || die
|
|
fi
|
|
}
|