mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-02-19 04:47:29 -08:00
1f913035f1
With ipython6+ dropping py2 and ipython having a circular dependency with ipykernel and ipyparallel, things get messy and portage's error messages are unhelpful unless we have a clean break in our dependencies. With this commit, all <ipykernel-5 depend on <ipython-6 and all >=ipykernel-5 depend on >=ipython-6. This makes portage's dependency resolution much happier and results in helpful error messages indicating what packages need "-python_targets_python2_7". Bug: https://bugs.gentoo.org/684962 Signed-off-by: Virgil Dupras <vdupras@gentoo.org> Package-Manager: Portage-2.3.62, Repoman-2.3.11
45 lines
1.0 KiB
Bash
45 lines
1.0 KiB
Bash
# Copyright 1999-2019 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=6
|
|
|
|
PYTHON_COMPAT=( python2_7 python3_{5,6} )
|
|
PYTHON_REQ_USE="threads(+)"
|
|
|
|
inherit distutils-r1
|
|
|
|
DESCRIPTION="IPython Kernel for Jupyter"
|
|
HOMEPAGE="https://github.com/ipython/ipykernel"
|
|
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
|
|
|
|
LICENSE="BSD"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64 ~arm64 ~x86 ~amd64-linux ~x86-linux"
|
|
IUSE="test"
|
|
|
|
RDEPEND="
|
|
<dev-python/ipython-6[${PYTHON_USEDEP}]
|
|
dev-python/jupyter_client[${PYTHON_USEDEP}]
|
|
>=dev-python/traitlets-4.1.0[${PYTHON_USEDEP}]
|
|
>=www-servers/tornado-4.0[${PYTHON_USEDEP}]
|
|
"
|
|
DEPEND="${RDEPEND}
|
|
dev-python/setuptools[${PYTHON_USEDEP}]
|
|
test? (
|
|
dev-python/nose[${PYTHON_USEDEP}]
|
|
dev-python/nose_warnings_filters[${PYTHON_USEDEP}]
|
|
)
|
|
"
|
|
|
|
python_install() {
|
|
distutils-r1_python_install
|
|
|
|
# bug 628222, specify python 2 or 3.
|
|
sed -e "s:python:${EPYTHON%.*}:" \
|
|
-i "${ED}"usr/share/jupyter/kernels/${EPYTHON%.*}/kernel.json || die
|
|
}
|
|
|
|
python_test() {
|
|
nosetests --verbose ipykernel || die
|
|
}
|