mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2025-12-21 21:17:37 -08:00
015cd899c4
Closes: https://bugs.gentoo.org/947819 Signed-off-by: Lukas Schmelting <lschmelting@posteo.com> Part-of: https://github.com/gentoo/gentoo/pull/44958 Closes: https://github.com/gentoo/gentoo/pull/44958 Signed-off-by: Pacho Ramos <pacho@gentoo.org>
73 lines
1.5 KiB
Bash
73 lines
1.5 KiB
Bash
# Copyright 2022-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
PYTHON_COMPAT=( python3_{11..14} )
|
|
inherit gnome.org meson python-any-r1 vala virtualx xdg
|
|
|
|
DESCRIPTION="Building blocks for modern GNOME applications"
|
|
HOMEPAGE="https://gnome.pages.gitlab.gnome.org/libadwaita/ https://gitlab.gnome.org/GNOME/libadwaita"
|
|
|
|
LICENSE="LGPL-2.1+"
|
|
SLOT="1"
|
|
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
|
|
|
|
IUSE="doc examples +introspection test +vala"
|
|
REQUIRED_USE="
|
|
doc? ( introspection )
|
|
vala? ( introspection )
|
|
"
|
|
|
|
RDEPEND="
|
|
>=dev-libs/glib-2.80.0:2
|
|
>=gui-libs/gtk-4.19.4:4[introspection?]
|
|
dev-libs/appstream:=
|
|
dev-libs/fribidi
|
|
introspection? ( >=dev-libs/gobject-introspection-1.83.2:= )
|
|
"
|
|
DEPEND="${RDEPEND}
|
|
"
|
|
BDEPEND="
|
|
${PYTHON_DEPS}
|
|
doc? ( >=dev-util/gi-docgen-2021.1 )
|
|
vala? ( $(vala_depend) )
|
|
dev-util/glib-utils
|
|
sys-devel/gettext
|
|
virtual/pkgconfig
|
|
dev-lang/sassc
|
|
"
|
|
|
|
src_prepare() {
|
|
default
|
|
use vala && vala_setup
|
|
xdg_environment_reset
|
|
}
|
|
|
|
src_configure() {
|
|
local emesonargs=(
|
|
# Never use gi-docgen subproject
|
|
--wrap-mode nofallback
|
|
|
|
-Dprofiling=false
|
|
$(meson_feature introspection)
|
|
$(meson_use vala vapi)
|
|
$(meson_use doc documentation)
|
|
$(meson_use test tests)
|
|
$(meson_use examples)
|
|
)
|
|
meson_src_configure
|
|
}
|
|
|
|
src_test() {
|
|
addwrite /dev/dri
|
|
virtx meson_src_test --timeout-multiplier 2
|
|
}
|
|
|
|
src_install() {
|
|
meson_src_install
|
|
if use doc; then
|
|
mv "${ED}"/usr/share/doc/{${PN}-${SLOT},${PF}/html} || die
|
|
fi
|
|
}
|