mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2025-12-21 21:17:37 -08:00
2d25fad95c
Bug: https://bugs.gentoo.org/473598 Bug: https://bugs.gentoo.org/720224 Signed-off-by: Fabian Groffen <grobian@gentoo.org>
64 lines
1.5 KiB
Bash
64 lines
1.5 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
inherit flag-o-matic gnustep-base multilib virtualx
|
|
|
|
DESCRIPTION="Library of GUI classes written in Obj-C"
|
|
HOMEPAGE="https://gnustep.github.io/"
|
|
SRC_URI="https://ftp.gnustep.org/pub/gnustep/core/${P}.tar.gz"
|
|
|
|
LICENSE="LGPL-2.1"
|
|
SLOT="0"
|
|
KEYWORDS="~alpha amd64 ppc ~sparc x86"
|
|
IUSE="cups icu jpeg png speech"
|
|
|
|
DEPEND="${GNUSTEP_CORE_DEPEND}
|
|
app-text/aspell
|
|
>=gnustep-base/gnustep-base-1.3.0:=[icu?]
|
|
media-libs/audiofile
|
|
>=media-libs/giflib-4.1:=
|
|
>=media-libs/tiff-3:=
|
|
x11-libs/libXt
|
|
cups? ( >=net-print/cups-1.7.4:= )
|
|
icu? ( dev-libs/icu:= )
|
|
jpeg? ( media-libs/libjpeg-turbo:= )
|
|
png? ( >=media-libs/libpng-1.2:= )
|
|
speech? ( app-accessibility/flite )"
|
|
RDEPEND="${DEPEND}"
|
|
|
|
src_prepare() {
|
|
gnustep-base_src_prepare
|
|
|
|
# remove hardcoded -g -Werror, bug #378179
|
|
sed -i -e 's/-g -Werror//' \
|
|
Tools/say/GNUmakefile \
|
|
Tools/speech/GNUmakefile \
|
|
|| die
|
|
|
|
# test failures.
|
|
rm -r Tests/gui/NSPasteboard/ || die # bug #935828
|
|
sed -e '/START_SET/aSKIP("Skipped by the ebuild bug #941901");' -i Tests/gui/NSSavePanel/setDelegate_reload.m || die
|
|
}
|
|
|
|
src_configure() {
|
|
# lto-type-mismatch
|
|
filter-lto
|
|
|
|
egnustep_env
|
|
|
|
econf \
|
|
$(use_enable cups) \
|
|
$(use_enable icu) \
|
|
$(use_enable jpeg) \
|
|
$(use_enable png) \
|
|
$(use_enable speech) \
|
|
--disable-ungif --enable-libgif \
|
|
--with-tiff-include="${EPREFIX}"/usr/include \
|
|
--with-tiff-library="${EPREFIX}"/usr/$(get_libdir)
|
|
}
|
|
|
|
src_test() {
|
|
virtx default
|
|
}
|