mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-01-06 02:17:34 -08:00
92561523ab
Now uses SDL2. ebuild changes: * EAPI6->8 * fix licenses wrt bug #880183 (minus public-domain, binreloc.c is not in this version) * update HOMEPAGE, old domain seems dead * tentatively drop -O? -> -O0 replace-flags, many changes including using C++ and hopefully is not relevant anymore (or at least, I can load save games even with -O3) -> also drop filter-flags, it had no arguments and was no-op (likely was meant to be strip-flags) * change windres workaround to not need a patch (note it gives a misleading error about lacking Ogg support, but if look at debug output it successfully finds Ogg differently) Closes: https://bugs.gentoo.org/880183 Signed-off-by: Ionen Wolkens <ionen@gentoo.org>
51 lines
1.1 KiB
Bash
51 lines
1.1 KiB
Bash
# Copyright 1999-2022 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
inherit xdg
|
|
|
|
DESCRIPTION="Dink Smallwood is an adventure/role-playing game, similar to Zelda (2D top view)"
|
|
HOMEPAGE="https://www.gnu.org/s/freedink/"
|
|
SRC_URI="mirror://gnu/freedink/${P}.tar.gz"
|
|
|
|
LICENSE="GPL-3+ LGPL-2.1+"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64 ~x86"
|
|
|
|
COMMON_DEPEND="
|
|
media-libs/fontconfig
|
|
media-libs/libsdl2[joystick,sound,video]
|
|
media-libs/sdl2-gfx
|
|
media-libs/sdl2-image
|
|
media-libs/sdl2-mixer[midi,vorbis,wav]
|
|
media-libs/sdl2-ttf"
|
|
RDEPEND="
|
|
${COMMON_DEPEND}
|
|
games-rpg/freedink-data"
|
|
DEPEND="
|
|
${COMMON_DEPEND}
|
|
media-libs/glm"
|
|
BDEPEND="
|
|
sys-devel/gettext
|
|
virtual/pkgconfig"
|
|
|
|
PATCHES=(
|
|
"${FILESDIR}"/${P}-odr.patch
|
|
"${FILESDIR}"/${P}-sdl.patch
|
|
)
|
|
|
|
src_configure() {
|
|
local econfargs=(
|
|
# TODO? Needs unpackaged cxxtest, but that package (currently) seem
|
|
# dead and may not be worth adding just for testing this.
|
|
--disable-tests
|
|
|
|
# Fails if finds a windres executable
|
|
ac_cv_prog_WINDRES=
|
|
ac_cv_prog_ac_ct_WINDRES=
|
|
)
|
|
|
|
econf "${econfargs[@]}"
|
|
}
|