mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2025-12-21 21:17:37 -08:00
75 lines
1.4 KiB
Bash
75 lines
1.4 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
PYTHON_COMPAT=( python3_{11..13} )
|
|
LLVM_COMPAT=( {16..20} )
|
|
inherit cmake llvm-r1 python-single-r1
|
|
|
|
DESCRIPTION="Super-parallel Python port of the C-Reduce"
|
|
HOMEPAGE="https://github.com/marxin/cvise/"
|
|
SRC_URI="
|
|
https://github.com/marxin/cvise/archive/v${PV}.tar.gz -> ${P}.tar.gz
|
|
"
|
|
|
|
LICENSE="UoI-NCSA"
|
|
SLOT="0"
|
|
KEYWORDS="amd64 arm arm64 ~loong ppc ppc64 ~riscv ~sparc x86"
|
|
IUSE="test"
|
|
RESTRICT="!test? ( test )"
|
|
REQUIRED_USE=${PYTHON_REQUIRED_USE}
|
|
|
|
DEPEND="
|
|
$(llvm_gen_dep '
|
|
llvm-core/clang:${LLVM_SLOT}
|
|
llvm-core/llvm:${LLVM_SLOT}
|
|
')
|
|
"
|
|
RDEPEND="
|
|
${DEPEND}
|
|
${PYTHON_DEPS}
|
|
$(python_gen_cond_dep '
|
|
dev-python/chardet[${PYTHON_USEDEP}]
|
|
dev-python/pebble[${PYTHON_USEDEP}]
|
|
dev-python/psutil[${PYTHON_USEDEP}]
|
|
')
|
|
dev-util/unifdef
|
|
app-alternatives/lex
|
|
"
|
|
BDEPEND="
|
|
${PYTHON_DEPS}
|
|
app-alternatives/lex
|
|
test? (
|
|
$(python_gen_cond_dep '
|
|
dev-python/pebble[${PYTHON_USEDEP}]
|
|
dev-python/pytest[${PYTHON_USEDEP}]
|
|
')
|
|
)
|
|
"
|
|
|
|
PATCHES=(
|
|
"${FILESDIR}"/${P}-llvm20.patch
|
|
)
|
|
|
|
pkg_setup() {
|
|
python-single-r1_pkg_setup
|
|
llvm-r1_pkg_setup
|
|
}
|
|
|
|
src_prepare() {
|
|
sed -i -e 's:-Werror::' -e '/CMAKE_CXX_FLAGS_REL/d' CMakeLists.txt || die
|
|
cmake_src_prepare
|
|
}
|
|
|
|
src_test() {
|
|
cd "${BUILD_DIR}" || die
|
|
epytest
|
|
}
|
|
|
|
src_install() {
|
|
cmake_src_install
|
|
|
|
python_fix_shebang "${ED}"
|
|
}
|