mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-04-30 04:47:28 -07:00
129c96c90e
Tests pass for all slots. Bug: https://bugs.gentoo.org/971953 Signed-off-by: Christopher Fore <csfore@gentoo.org> Part-of: https://codeberg.org/gentoo/gentoo/pulls/510 Merges: https://codeberg.org/gentoo/gentoo/pulls/510 Signed-off-by: Sam James <sam@gentoo.org>
44 lines
991 B
Bash
44 lines
991 B
Bash
# Copyright 1999-2026 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
USE_RUBY="ruby32 ruby33 ruby34"
|
|
|
|
RUBY_FAKEGEM_BINWRAP=""
|
|
RUBY_FAKEGEM_EXTRADOC="README.md"
|
|
RUBY_FAKEGEM_GEMSPEC="phlex.gemspec"
|
|
RUBY_FAKEGEM_RECIPE_TEST="sus"
|
|
|
|
inherit ruby-fakegem
|
|
|
|
DESCRIPTION="A framework for building object-oriented views in Ruby"
|
|
HOMEPAGE="https://github.com/yippee-fun/phlex"
|
|
SRC_URI="https://github.com/yippee-fun/phlex/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
|
|
|
|
LICENSE="MIT"
|
|
SLOT="$(ver_cut 1-2)"
|
|
KEYWORDS="~amd64"
|
|
IUSE="test"
|
|
|
|
ruby_add_rdepend ">=dev-ruby/zeitwerk-2.7:2"
|
|
|
|
ruby_add_bdepend "test? (
|
|
>=dev-ruby/concurrent-ruby-1.2:1
|
|
)"
|
|
|
|
all_ruby_prepare() {
|
|
sed -e 's:_relative ": "./:' \
|
|
-e 's/__dir__/"."/' \
|
|
-i ${RUBY_FAKEGEM_GEMSPEC} || die
|
|
|
|
sed -e '/bundler/I s:^:#:' \
|
|
-e '1irequire "concurrent"' \
|
|
-e '/simplecov/,/SimpleCov.command_name/ s:^:#:' \
|
|
-i config/sus.rb || die
|
|
}
|
|
|
|
each_ruby_test() {
|
|
RUBYLIB=lib each_fakegem_test
|
|
}
|