mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-04-29 16:37:30 -07:00
9a07e6038a
The package imports from distutils, so it requires setuptools on newer Python versions. Let's make it use them unconditionally. Signed-off-by: Michał Górny <mgorny@gentoo.org>
54 lines
1.2 KiB
Bash
54 lines
1.2 KiB
Bash
# Copyright 1999-2026 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
DISTUTILS_USE_PEP517=no
|
|
PYPI_PN=setuptools
|
|
PYTHON_COMPAT=( python3_{11..14} pypy3_11 )
|
|
PYTHON_REQ_USE="xml(+)"
|
|
|
|
inherit distutils-r1 pypi
|
|
|
|
DESCRIPTION="pkg_resources package split from old setuptools"
|
|
HOMEPAGE="
|
|
https://github.com/pypa/setuptools/
|
|
https://pypi.org/project/setuptools/
|
|
"
|
|
|
|
LICENSE="MIT"
|
|
SLOT="0"
|
|
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~arm64-macos ~x64-macos ~x64-solaris"
|
|
|
|
RDEPEND="
|
|
>=dev-python/jaraco-text-4.0.0[${PYTHON_USEDEP}]
|
|
>=dev-python/packaging-25.0[${PYTHON_USEDEP}]
|
|
>=dev-python/platformdirs-4.4.0[${PYTHON_USEDEP}]
|
|
!<dev-python/setuptools-82
|
|
"
|
|
BDEPEND="
|
|
test? (
|
|
dev-python/setuptools[${PYTHON_USEDEP}]
|
|
)
|
|
"
|
|
|
|
EPYTEST_PLUGINS=()
|
|
distutils_enable_tests pytest
|
|
|
|
EPYTEST_IGNORE=(
|
|
# requires setuptools wheel
|
|
pkg_resources/tests/test_integration_zope_interface.py
|
|
)
|
|
|
|
python_test() {
|
|
# needed only by setuptools
|
|
rm -f conftest.py || die
|
|
epytest -o filterwarnings= pkg_resources
|
|
}
|
|
|
|
python_install() {
|
|
# Let's install the module manually. We don't want a fake .dist-info
|
|
# for it.
|
|
python_domodule pkg_resources
|
|
}
|