mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-04-28 16:17:38 -07:00
b9732108d6
Closes: https://bugs.gentoo.org/972911 Signed-off-by: Alfred Wingate <parona@protonmail.com> Part-of: https://codeberg.org/gentoo/gentoo/pulls/706 Merges: https://codeberg.org/gentoo/gentoo/pulls/706 Signed-off-by: Michał Górny <mgorny@gentoo.org>
52 lines
1.1 KiB
Bash
52 lines
1.1 KiB
Bash
# Copyright 2023-2026 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
DISTUTILS_EXT=1
|
|
DISTUTILS_USE_PEP517=maturin
|
|
PYPI_VERIFY_REPO=https://github.com/ijl/orjson
|
|
PYTHON_COMPAT=( python3_{11..14} )
|
|
|
|
# upstream is vendoring crates, so we don't need CRATES.
|
|
RUST_MAX_VER="1.94.1" # bug #972911
|
|
RUST_MIN_VER="1.89.0"
|
|
|
|
inherit cargo distutils-r1 pypi
|
|
|
|
DESCRIPTION="Fast, correct Python JSON library supporting dataclasses, datetimes, and numpy"
|
|
HOMEPAGE="
|
|
https://github.com/ijl/orjson/
|
|
https://pypi.org/project/orjson/
|
|
"
|
|
|
|
LICENSE="|| ( Apache-2.0 MIT )"
|
|
# Dependent crate licenses
|
|
LICENSE+="
|
|
Apache-2.0-with-LLVM-exceptions BSD Boost-1.0 MIT Unicode-3.0
|
|
"
|
|
SLOT="0"
|
|
KEYWORDS="amd64 arm arm64 ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
|
|
|
|
BDEPEND="
|
|
>=dev-util/maturin-1.7.8[${PYTHON_USEDEP}]
|
|
test? (
|
|
dev-python/arrow[${PYTHON_USEDEP}]
|
|
dev-python/numpy[${PYTHON_USEDEP}]
|
|
dev-python/psutil[${PYTHON_USEDEP}]
|
|
dev-python/pytz[${PYTHON_USEDEP}]
|
|
)
|
|
"
|
|
|
|
QA_FLAGS_IGNORED=".*"
|
|
|
|
EPYTEST_PLUGINS=()
|
|
distutils_enable_tests pytest
|
|
|
|
src_unpack() {
|
|
pypi_src_unpack
|
|
|
|
# https://github.com/ijl/orjson/issues/613
|
|
cargo_gen_config
|
|
}
|