mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-01-04 01:37:34 -08:00
0ad96e879b
Result of running the command: grep --include="*.ebuild" -r . -e 'KEYWORDS=.*[" ]sparc' -l | xargs ekeyword ~sparc Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>
70 lines
1.6 KiB
Bash
70 lines
1.6 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
DISTUTILS_USE_PEP517=hatchling
|
|
PYTHON_COMPAT=( pypy3_11 python3_{11..14} )
|
|
|
|
inherit distutils-r1 optfeature
|
|
|
|
DESCRIPTION="A minimal low-level HTTP client"
|
|
HOMEPAGE="
|
|
https://www.encode.io/httpcore/
|
|
https://github.com/encode/httpcore/
|
|
https://pypi.org/project/httpcore/
|
|
"
|
|
SRC_URI="
|
|
https://github.com/encode/httpcore/archive/${PV}.tar.gz
|
|
-> ${P}.gh.tar.gz
|
|
"
|
|
|
|
LICENSE="BSD"
|
|
SLOT="0"
|
|
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
|
|
|
|
RDEPEND="
|
|
<dev-python/anyio-5[${PYTHON_USEDEP}]
|
|
dev-python/certifi[${PYTHON_USEDEP}]
|
|
>=dev-python/h11-0.16[${PYTHON_USEDEP}]
|
|
<dev-python/h2-5[${PYTHON_USEDEP}]
|
|
=dev-python/sniffio-1*[${PYTHON_USEDEP}]
|
|
"
|
|
BDEPEND="
|
|
dev-python/hatch-fancy-pypi-readme[${PYTHON_USEDEP}]
|
|
test? (
|
|
dev-python/pytest-asyncio[${PYTHON_USEDEP}]
|
|
dev-python/pytest-httpbin[${PYTHON_USEDEP}]
|
|
dev-python/socksio[${PYTHON_USEDEP}]
|
|
dev-python/trustme[${PYTHON_USEDEP}]
|
|
$(python_gen_cond_dep '
|
|
dev-python/pytest-trio[${PYTHON_USEDEP}]
|
|
dev-python/trio[${PYTHON_USEDEP}]
|
|
' 3.{11..13})
|
|
)
|
|
"
|
|
|
|
distutils_enable_tests pytest
|
|
|
|
python_test() {
|
|
local opts=()
|
|
local EPYTEST_IGNORE=()
|
|
|
|
if ! has_version "dev-python/trio[${PYTHON_USEDEP}]"; then
|
|
opts+=( -k "not trio" )
|
|
EPYTEST_IGNORE+=(
|
|
tests/_async/test_connection_pool.py
|
|
)
|
|
fi
|
|
|
|
if ! has_version "dev-python/pytest-trio[${PYTHON_USEDEP}]"; then
|
|
opts+=( -m "not trio" -o addopts= )
|
|
fi
|
|
|
|
epytest "${opts[@]}"
|
|
}
|
|
|
|
pkg_postinst() {
|
|
optfeature "SOCKS support" dev-python/socksio
|
|
}
|