mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-05-01 05:08:10 -07:00
3a7e25bf83
Partial py3.14 support is available since 1.108.0 which is good enough for us. Add py3.14 to 1.108.0 to get it to a stable candidate sooner. Signed-off-by: Alfred Wingate <parona@protonmail.com> Part-of: https://codeberg.org/gentoo/gentoo/pulls/697 Signed-off-by: Michał Górny <mgorny@gentoo.org>
62 lines
1.5 KiB
Bash
62 lines
1.5 KiB
Bash
# Copyright 1999-2026 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
DISTUTILS_USE_PEP517=setuptools
|
|
PYTHON_COMPAT=( python3_{11..14} )
|
|
|
|
inherit distutils-r1
|
|
|
|
MY_P=serverless-application-model-${PV}
|
|
DESCRIPTION="A library that transform SAM templates into AWS CloudFormation templates"
|
|
HOMEPAGE="
|
|
https://github.com/aws/serverless-application-model/
|
|
https://pypi.org/project/aws-sam-translator/
|
|
"
|
|
SRC_URI="
|
|
https://github.com/aws/serverless-application-model/archive/v${PV}.tar.gz
|
|
-> ${MY_P}.gh.tar.gz
|
|
"
|
|
S=${WORKDIR}/${MY_P}
|
|
|
|
LICENSE="Apache-2.0"
|
|
SLOT="0"
|
|
KEYWORDS="amd64 ~arm arm64 ~ppc64 ~riscv x86"
|
|
|
|
RDEPEND="
|
|
<dev-python/boto3-2[${PYTHON_USEDEP}]
|
|
>=dev-python/boto3-1.34.0[${PYTHON_USEDEP}]
|
|
>=dev-python/jsonschema-4.23[${PYTHON_USEDEP}]
|
|
<dev-python/pydantic-3[${PYTHON_USEDEP}]
|
|
>=dev-python/pydantic-2.12.5[${PYTHON_USEDEP}]
|
|
<dev-python/typing-extensions-5[${PYTHON_USEDEP}]
|
|
>=dev-python/typing-extensions-4.4[${PYTHON_USEDEP}]
|
|
dev-python/pyyaml[${PYTHON_USEDEP}]
|
|
"
|
|
BDEPEND="
|
|
test? (
|
|
dev-python/mock[${PYTHON_USEDEP}]
|
|
dev-python/parameterized[${PYTHON_USEDEP}]
|
|
)
|
|
"
|
|
|
|
EPYTEST_PLUGINS=()
|
|
EPYTEST_XDIST=1
|
|
distutils_enable_tests pytest
|
|
|
|
python_prepare_all() {
|
|
# so much noise...
|
|
sed -i -e '/log_cli/d' pytest.ini || die
|
|
|
|
# deps are installed by ebuild, don't try to reinstall them via pip
|
|
truncate --size=0 requirements/*.txt || die
|
|
|
|
distutils-r1_python_prepare_all
|
|
}
|
|
|
|
python_test() {
|
|
local -x AWS_DEFAULT_REGION=us-east-1
|
|
epytest -o addopts= -o filterwarnings=
|
|
}
|