mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-24 18:58:08 -07:00
f153304506
Tested-by: ernsteiswuerfel <erhard_f@mailbox.org> Signed-off-by: Eli Schwartz <eschwartz@gentoo.org>
70 lines
1.9 KiB
Bash
70 lines
1.9 KiB
Bash
# Copyright 1999-2026 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
# Should be bumped with media-plugins/gst-plugins-libnice
|
|
|
|
EAPI=8
|
|
|
|
inherit meson-multilib xdg
|
|
|
|
DESCRIPTION="Implementation of the Interactive Connectivity Establishment standard (ICE)"
|
|
HOMEPAGE="https://libnice.freedesktop.org/"
|
|
SRC_URI="https://libnice.freedesktop.org/releases/${P}.tar.gz"
|
|
|
|
LICENSE="|| ( MPL-1.1 LGPL-2.1 )"
|
|
SLOT="0"
|
|
KEYWORDS="~alpha amd64 ~arm arm64 ~hppa ~loong ppc ppc64 ~riscv ~sparc x86"
|
|
IUSE="+gnutls gtk-doc +introspection test +upnp"
|
|
RESTRICT="!test? ( test )"
|
|
|
|
RDEPEND="
|
|
>=dev-libs/glib-2.56:2[${MULTILIB_USEDEP}]
|
|
introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2:= )
|
|
gnutls? ( >=net-libs/gnutls-3.6.0:=[${MULTILIB_USEDEP}] )
|
|
!gnutls? ( dev-libs/openssl:=[${MULTILIB_USEDEP}] )
|
|
upnp? ( >=net-libs/gupnp-igd-0.2.5:1.6=[${MULTILIB_USEDEP}] )
|
|
"
|
|
DEPEND="${RDEPEND}"
|
|
BDEPEND="
|
|
dev-util/glib-utils
|
|
virtual/pkgconfig
|
|
gtk-doc? (
|
|
app-text/docbook-xml-dtd:4.1.2
|
|
dev-util/gtk-doc
|
|
)
|
|
"
|
|
|
|
PATCHES=(
|
|
"${FILESDIR}/${PN}-0.1.19-remove-graphviz-dependency.patch" # downstream; bugs 877451, 889820
|
|
"${FILESDIR}/${PN}-0.1.22-gupnp-igd-1.6.patch" # downstream; bugs 948374, 953635
|
|
"${FILESDIR}/${PN}-0.1.23-fix-test-pseudotcp.patch" # bug 836632
|
|
)
|
|
|
|
src_prepare() {
|
|
default
|
|
|
|
# skip tests which break with network-sandbox enabled; bugs 847844
|
|
sed -i \
|
|
-e "/test-set-port-range/d" \
|
|
-e "/test-slow-resolving',/d" \
|
|
tests/meson.build || die
|
|
}
|
|
|
|
multilib_src_configure() {
|
|
# gstreamer plugin split off into media-plugins/gst-plugins-libnice
|
|
local emesonargs=(
|
|
-Dgstreamer=disabled
|
|
-Dcrypto-library=$(usex gnutls gnutls openssl)
|
|
$(meson_native_use_feature introspection)
|
|
$(meson_feature test tests)
|
|
$(meson_feature upnp gupnp)
|
|
$(meson_native_use_feature gtk-doc gtk_doc)
|
|
)
|
|
|
|
meson_src_configure
|
|
}
|
|
|
|
multilib_src_install_all() {
|
|
einstalldocs
|
|
}
|