mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-24 18:58:08 -07:00
9e8d0acdcb
This is similar tod83e25b6a5. Adapted parona's sed then checked results: ``` $ sed -E '/dev-util\/gdbus-codegen(:=|\s|$|-[0-9]|\[)/ { s/(>=)?dev-util\/gdbus-codegen(-[0-9.r-]*)?/>=dev-util\/gdbus-codegen-2.80.5-r1/ }' */*/*.ebuild -i ``` We need to make the PM upgrade to newer gdbus-codegen (seeda84c0959e). Otherwise, a gdbus-codegen that is broken (even if we added a newer version and dropped old etc) may be used to build other packages and cause build failures. Bug: https://bugs.gentoo.org/919904 Bug: https://bugs.gentoo.org/922654 Bug: https://bugs.gentoo.org/959259 Signed-off-by: Sam James <sam@gentoo.org>
48 lines
1.1 KiB
Bash
48 lines
1.1 KiB
Bash
# Copyright 1999-2026 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
inherit gnome.org meson-multilib vala
|
|
|
|
DESCRIPTION="DBus API that allows cloud storage sync clients to expose their services"
|
|
HOMEPAGE="https://gitlab.gnome.org/World/libcloudproviders"
|
|
|
|
LICENSE="LGPL-3"
|
|
SLOT="0"
|
|
IUSE="gtk-doc +introspection vala"
|
|
REQUIRED_USE="vala? ( introspection )"
|
|
|
|
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
|
|
|
|
DEPEND="
|
|
>=dev-libs/glib-2.56:2[${MULTILIB_USEDEP}]
|
|
introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2 )"
|
|
RDEPEND="${DEPEND}"
|
|
BDEPEND="
|
|
>=dev-util/gdbus-codegen-2.80.5-r1
|
|
dev-util/glib-utils
|
|
virtual/pkgconfig
|
|
gtk-doc? ( dev-util/gtk-doc )
|
|
vala? ( $(vala_depend) )
|
|
"
|
|
|
|
src_prepare() {
|
|
default
|
|
use vala && vala_setup
|
|
}
|
|
|
|
multilib_src_configure() {
|
|
local emesonargs=(
|
|
$(meson_native_use_bool gtk-doc enable-gtk-doc)
|
|
-Dinstalled-tests=false
|
|
$(meson_native_use_bool introspection)
|
|
$(meson_native_use_bool vala vapigen)
|
|
)
|
|
meson_src_configure
|
|
}
|
|
|
|
multilib_src_install() {
|
|
meson_src_install
|
|
}
|