mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-05 12:38:09 -07:00
72f0637a98
Closes: https://bugs.gentoo.org/975424 Signed-off-by: Daniel Pielmeier <billie@gentoo.org>
63 lines
1.3 KiB
Bash
63 lines
1.3 KiB
Bash
# Copyright 1999-2026 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=9
|
|
MY_PF=${P/_p2/}
|
|
MY_P=${MY_PF}.pl02
|
|
|
|
inherit autotools
|
|
|
|
DESCRIPTION="Open-source library for reading, mastering and writing optical discs"
|
|
HOMEPAGE="https://dev.lovelyhq.com/libburnia/web/wiki/Libisofs https://dev.lovelyhq.com/libburnia/libisofs"
|
|
SRC_URI="https://files.libburnia-project.org/releases/${MY_P}.tar.gz"
|
|
|
|
S="${WORKDIR}/${MY_PF}"
|
|
|
|
LICENSE="GPL-2"
|
|
SLOT="0"
|
|
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
|
|
IUSE="acl debug lfa-flags projid static-libs xattr zlib"
|
|
|
|
BDEPEND="
|
|
virtual/pkgconfig
|
|
"
|
|
RDEPEND="
|
|
acl? ( virtual/acl )
|
|
xattr? ( sys-apps/attr )
|
|
zlib? ( virtual/zlib:= )
|
|
"
|
|
DEPEND="
|
|
${RDEPEND}
|
|
"
|
|
|
|
src_prepare() {
|
|
default
|
|
|
|
# Ancient libtool version in 1.5.6 at least (debian's 2.4.2-1.11)
|
|
eautoreconf
|
|
}
|
|
|
|
src_configure() {
|
|
econf \
|
|
$(use_enable static-libs static) \
|
|
$(use_enable debug) \
|
|
--disable-verbose-debug \
|
|
$(use_enable acl libacl) \
|
|
$(use_enable xattr) \
|
|
$(use_enable lfa-flags) \
|
|
$(use_enable projid) \
|
|
$(use_enable zlib) \
|
|
--disable-libjte \
|
|
--disable-dir-rec-size-check \
|
|
--enable-versioned-libs \
|
|
--disable-ldconfig-at-install
|
|
}
|
|
|
|
src_install() {
|
|
default
|
|
|
|
dodoc Roadmap doc/{*.txt,Tutorial}
|
|
|
|
find "${D}" -name '*.la' -delete || die
|
|
}
|