mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-18 02:59:07 -07:00
55 lines
1.2 KiB
Bash
55 lines
1.2 KiB
Bash
# Copyright 1999-2026 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
inherit gap-pkg
|
|
|
|
MY_PN=GAPDoc
|
|
MY_P="${MY_PN}-${PV}"
|
|
DESCRIPTION="GAP documentation structure and tooling"
|
|
|
|
# Release archives contain the tests (generated by maketest.g), Github
|
|
# tags do not.
|
|
SRC_URI="https://www.math.rwth-aachen.de/~Frank.Luebeck/${MY_PN}/${MY_PN}-${PV}.tar.gz"
|
|
S="${WORKDIR}/${MY_PN}-${PV}"
|
|
|
|
LICENSE="GPL-2+"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64 ~riscv"
|
|
IUSE="examples test"
|
|
RESTRICT="!test? ( test )"
|
|
|
|
BDEPEND="test? (
|
|
dev-gap/browse
|
|
)"
|
|
|
|
PATCHES=( "${FILESDIR}/${P}-load-browse-in-tests.patch" )
|
|
|
|
DOCS=( CHANGES README.md )
|
|
|
|
GAP_PKG_EXTRA_INSTALL=(
|
|
bibxmlext.dtd
|
|
gapdoc.dtd
|
|
styles
|
|
version
|
|
)
|
|
|
|
src_install(){
|
|
gap-pkg_src_install
|
|
|
|
if use examples; then
|
|
docinto examples
|
|
dodoc -r 3k+1
|
|
fi
|
|
|
|
# The "example" directory is mentioned in PackageInfo.g, so we
|
|
# include it unconditionally, and install it in the gap package
|
|
# directory (so that the path in PackageInfo.g is accurate).
|
|
# Afterwards we symlink it into the usual USE=examples path.
|
|
insinto $(gap-pkg_dir)
|
|
doins -r example
|
|
dosym -r $(gap-pkg_dir)/example \
|
|
"/usr/share/doc/${PF}/examples/example"
|
|
}
|