mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-01 11:18:09 -07:00
2fd6c2357d
I thought this built OK against the new libplanarity, but bug 977995 reveals that the build system was falling back to a bundled copy of planarity-4.x. The new revision requires >= planarity-5, supported with a patch (and eautoreconf), and deletes the bundled libraries to prevent similar mistakes in the future. Closes: https://bugs.gentoo.org/977995 Signed-off-by: Michael Orlitzky <mjo@gentoo.org>
55 lines
1.1 KiB
Bash
55 lines
1.1 KiB
Bash
# Copyright 1999-2026 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
inherit autotools gap-pkg
|
|
|
|
DESCRIPTION="Graphs, digraphs, and multidigraphs in GAP"
|
|
SRC_URI="https://github.com/digraphs/Digraphs/releases/download/v${PV}/${P}.tar.gz"
|
|
|
|
LICENSE="GPL-3+"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64 ~riscv"
|
|
|
|
DEPEND="sci-mathematics/gap:=
|
|
>=sci-mathematics/planarity-5:=
|
|
sci-libs/bliss:="
|
|
RDEPEND="${DEPEND}
|
|
dev-gap/io
|
|
dev-gap/orb
|
|
dev-gap/datastructures"
|
|
|
|
# There are a few tests that will fail without a PDF viewer installed.
|
|
# Having xdg-open is good enough, and light weight, so it goes first.
|
|
BDEPEND="test? ( || (
|
|
x11-misc/xdg-utils
|
|
app-text/gv
|
|
app-text/xpdf
|
|
app-text/evince
|
|
kde-apps/okular
|
|
) )"
|
|
|
|
DOCS=( CHANGELOG.md README.md )
|
|
|
|
PATCHES=( "${FILESDIR}/digraphs-1.14-planarity-5.patch" )
|
|
|
|
GAP_PKG_EXTRA_INSTALL=( data notebooks )
|
|
gap-pkg_enable_tests
|
|
|
|
src_prepare() {
|
|
# belt and suspenders
|
|
rm -r extern/bliss-0.73 \
|
|
extern/edge-addition-planarity-suite-Version_4.0.0.0 \
|
|
|| die
|
|
|
|
default
|
|
eautoreconf
|
|
}
|
|
|
|
src_configure() {
|
|
gap-pkg_econf \
|
|
--with-external-planarity \
|
|
--with-external-bliss
|
|
}
|