mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 04:59:14 -07:00
b26113ad39
GNU Make has many valid short ops and long ops, most of which are incompatible with bmake. We can either chase sanitization or do the sane thing, unset MAKEOPTS and MAKEFLAGS and pass just jobs Closes: https://bugs.gentoo.org/966238 Signed-off-by: NHOrus <jy6x2b32pie9@yahoo.com> Part-of: https://github.com/gentoo/gentoo/pull/44764 Closes: https://github.com/gentoo/gentoo/pull/44764 Signed-off-by: Sam James <sam@gentoo.org>
80 lines
1.5 KiB
Bash
80 lines
1.5 KiB
Bash
# Copyright 2021-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
inherit flag-o-matic multiprocessing toolchain-funcs
|
|
|
|
MY_PV="VERSION_${PV//./_}"
|
|
DESCRIPTION="Markdown translator producing HTML5, roff documents in the ms and man formats"
|
|
HOMEPAGE="https://kristaps.bsd.lv/lowdown/"
|
|
SRC_URI="https://github.com/kristapsdz/lowdown/archive/refs/tags/${MY_PV}.tar.gz -> ${P}.tar.gz"
|
|
S="${WORKDIR}/${PN}-${MY_PV}"
|
|
|
|
LICENSE="ISC"
|
|
SLOT="0/3"
|
|
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
|
|
|
|
DEPEND="
|
|
virtual/libcrypt:=
|
|
"
|
|
RDEPEND="
|
|
${DEPEND}
|
|
"
|
|
BDEPEND="
|
|
dev-build/bmake
|
|
"
|
|
|
|
# configure tests for a bunch of BSD functions on Linux
|
|
QA_CONFIG_IMPL_DECL_SKIP=(
|
|
crypt_newhash
|
|
crypt_checkpass
|
|
warnc
|
|
errc
|
|
getexecname
|
|
getprogname
|
|
memset_s
|
|
pledge
|
|
recallocarray
|
|
strlcat
|
|
strlcpy
|
|
strtonum
|
|
TAILQ_FOREACH_SAFE
|
|
unveil
|
|
arc4random
|
|
b64_ntop
|
|
)
|
|
|
|
PATCHES=(
|
|
"${FILESDIR}/lowdown-0.10.0-pkgconfig-libmd.patch"
|
|
"${FILESDIR}/lowdown-2.0.0-shared-linking.patch"
|
|
)
|
|
|
|
src_configure() {
|
|
append-flags -fPIC
|
|
tc-export CC AR
|
|
|
|
local jobs="$(makeopts_jobs)"
|
|
unset MAKEOPTS
|
|
unset MAKEFLAGS
|
|
|
|
export MAKEOPTS="-j${jobs}"
|
|
export MAKE=bmake
|
|
|
|
./configure \
|
|
PREFIX="${EPREFIX}/usr" \
|
|
MANDIR="${EPREFIX}/usr/share/man" \
|
|
LDFLAGS="${LDFLAGS}" \
|
|
CPPFLAGS="${CPPFLAGS}" \
|
|
LIBDIR="${EPREFIX}/usr/$(get_libdir)" \
|
|
|| die "./configure failed"
|
|
}
|
|
|
|
src_compile() {
|
|
emake $(usex elibc_musl UTF8_LOCALE=C.UTF-8 '')
|
|
}
|
|
|
|
src_test() {
|
|
LD_LIBRARY_PATH="${S}" emake regress
|
|
}
|