mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-24 18:58:08 -07:00
79232fd7de
Bundled version is serial 7. `dev-build/autoconf-archive-2024.10.16-r2` ships serial 25. Closes: https://bugs.gentoo.org/977602 Signed-off-by: Paul Zander <negril.nx+gentoo@gmail.com> Signed-off-by: Sam James <sam@gentoo.org>
55 lines
999 B
Bash
55 lines
999 B
Bash
# Copyright 1999-2026 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=9
|
|
|
|
inherit autotools
|
|
|
|
DESCRIPTION="Library parsing QuarkXpress documents"
|
|
HOMEPAGE="https://wiki.documentfoundation.org/DLP/Libraries/libqxp"
|
|
SRC_URI="https://dev-www.libreoffice.org/src/${PN}/${P}.tar.xz"
|
|
|
|
LICENSE="MPL-2.0"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
|
|
IUSE="debug doc test tools"
|
|
RESTRICT="!test? ( test )"
|
|
|
|
RDEPEND="
|
|
dev-libs/icu:=
|
|
dev-libs/librevenge
|
|
"
|
|
DEPEND="${RDEPEND}
|
|
dev-libs/boost
|
|
test? ( dev-util/cppunit )
|
|
"
|
|
BDEPEND="
|
|
virtual/pkgconfig
|
|
doc? ( app-text/doxygen )
|
|
"
|
|
|
|
src_prepare() {
|
|
default
|
|
|
|
# old bundled version
|
|
rm m4/ax_cxx_compile_stdcxx.m4 || die
|
|
|
|
eautoreconf
|
|
}
|
|
|
|
src_configure() {
|
|
local myeconfargs=(
|
|
--disable-weffc
|
|
$(use_enable debug)
|
|
$(use_with doc docs)
|
|
$(use_enable test tests)
|
|
$(use_enable tools)
|
|
)
|
|
econf "${myeconfargs[@]}"
|
|
}
|
|
|
|
src_install() {
|
|
default
|
|
find "${D}" -name '*.la' -type f -delete || die
|
|
}
|