From ff3627b2c6a0aeadb88e1b4119cf2f409df8914e Mon Sep 17 00:00:00 2001
From: Ionen Wolkens <ionen@gentoo.org>
Date: Fri, 14 Mar 2025 02:15:27 -0400
Subject: [PATCH] dev-qt/qtconnectivity: add 6.9.0_rc

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>
---
 dev-qt/qtconnectivity/Manifest                |  1 +
 .../qtconnectivity-6.9.0_rc.ebuild            | 85 +++++++++++++++++++
 2 files changed, 86 insertions(+)
 create mode 100644 dev-qt/qtconnectivity/qtconnectivity-6.9.0_rc.ebuild

diff --git a/dev-qt/qtconnectivity/Manifest b/dev-qt/qtconnectivity/Manifest
index 0ef8007254cc3..2675104170699 100644
--- a/dev-qt/qtconnectivity/Manifest
+++ b/dev-qt/qtconnectivity/Manifest
@@ -1 +1,2 @@
 DIST qtconnectivity-everywhere-src-6.8.2.tar.xz 1069068 BLAKE2B fcbb13ff28486586466eafec913fb6504ee6e79787e7bfa6362ea74ee755b70c390a2f2ebf96cdf74c875a33ab1673d296f497085e2b8c3b83d09ed9590b772f SHA512 b1310fc90c7a64a4d89586fd38119377b3b67ead57271c6713897d649b2154cd55bd07c97a53f12e7a9d720a1b8b6b630eeea43e44c6798f6313ea8e70e10767
+DIST qtconnectivity-everywhere-src-6.9.0-rc.tar.xz 1071492 BLAKE2B a8410cb681600c5f0b90071dbc05966254a1c1a95a256dd32330e2da8f8f7471ff475ad92667922f5aab4f1e73f61974bfafce463206c866cbc59d5f75c154af SHA512 d55c29ed88cc303c1692776306a69c2538ad99e107e322ce6343f1f9c52ece4a0f936eb6f3e95373ac821948d3219aad74a18d43648824f698089220acc9a60c
diff --git a/dev-qt/qtconnectivity/qtconnectivity-6.9.0_rc.ebuild b/dev-qt/qtconnectivity/qtconnectivity-6.9.0_rc.ebuild
new file mode 100644
index 0000000000000..32a29b47c968f
--- /dev/null
+++ b/dev-qt/qtconnectivity/qtconnectivity-6.9.0_rc.ebuild
@@ -0,0 +1,85 @@
+# Copyright 2023-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Bluetooth and NFC support library for the Qt6 framework"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+fi
+
+IUSE="+bluetooth neard nfc smartcard"
+REQUIRED_USE="
+	|| ( bluetooth nfc )
+	nfc? ( ?? ( neard smartcard ) )
+"
+
+DEPEND="
+	~dev-qt/qtbase-${PV}:6
+	bluetooth? (
+		~dev-qt/qtbase-${PV}:6[dbus,network]
+		net-wireless/bluez:=
+	)
+	nfc? (
+		neard? ( ~dev-qt/qtbase-${PV}:6[dbus] )
+		smartcard? ( sys-apps/pcsc-lite )
+	)
+"
+RDEPEND="
+	${DEPEND}
+	nfc? (
+		neard? ( net-wireless/neard )
+	)
+"
+
+CMAKE_SKIP_TESTS=(
+	# most hardware tests are auto-skipped, but some still misbehave
+	# if bluez/hardware is available (generally tests here may not be
+	# very relevant without hardware, lists may need to be extended)
+	tst_qbluetoothdevicediscoveryagent #936485
+	tst_qbluetoothlocaldevice
+	tst_qbluetoothserver
+	tst_qbluetoothservicediscoveryagent
+	tst_qbluetoothserviceinfo
+	tst_qlowenergycontroller
+)
+
+src_prepare() {
+	qt6-build_src_prepare
+
+	use bluetooth ||
+		sed -i '/add_subdirectory(bluetooth)/d' src/CMakeLists.txt || die
+	use nfc ||
+		sed -i '/add_subdirectory(nfc)/d' src/CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(usev nfc "
+			$(qt_feature neard)
+			$(qt_feature smartcard pcsclite)
+		")
+	)
+
+	qt6-build_src_configure
+}
+
+src_install() {
+	qt6-build_src_install
+
+	# broken (unnecessary) symlink due to add_app() being used over add_tool()
+	use !bluetooth || rm -- "${ED}"/usr/bin/sdpscanner6 || die
+
+	if use test; then
+		local delete=( # sigh
+			"${D}${QT6_BINDIR}"/bluetoothtestdevice
+			"${D}${QT6_BINDIR}"/bttestui
+			"${D}${QT6_BINDIR}"/qlecontroller-server
+		)
+		# using -f given not tracking which tests may be skipped or not
+		rm -f -- "${delete[@]}" || die
+	fi
+}