diff --git a/dev-python/nox/Manifest b/dev-python/nox/Manifest
new file mode 100644
index 0000000000000..bd4764d4b2253
--- /dev/null
+++ b/dev-python/nox/Manifest
@@ -0,0 +1 @@
+DIST nox-2022.11.21.gh.tar.gz 3983862 BLAKE2B 9c365dae5415de4c43c262a1ec9c9007b686838f8aff92a049b1602efe320b7644677646ee72c0e5754efc79d6e38cd46b59ff2851b39b4bf05d3166625000d4 SHA512 7f725425acd7d1ef55e04c5330c1f4fd2f2f5107c24b4bb7f7e2711cf6a5c1b8f2777a4902ee31d4a56898a953f3da6a9ed340d652fbc63cba33f5f763702b78
diff --git a/dev-python/nox/metadata.xml b/dev-python/nox/metadata.xml
new file mode 100644
index 0000000000000..ab6d02e2c2765
--- /dev/null
+++ b/dev-python/nox/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="github">wntrblm/nox</remote-id>
+		<remote-id type="pypi">nox</remote-id>
+	</upstream>
+</pkgmetadata>
diff --git a/dev-python/nox/nox-2022.11.21.ebuild b/dev-python/nox/nox-2022.11.21.ebuild
new file mode 100644
index 0000000000000..1047e05af66bf
--- /dev/null
+++ b/dev-python/nox/nox-2022.11.21.ebuild
@@ -0,0 +1,42 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{8..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Flexible test automation for Python"
+HOMEPAGE="
+	https://github.com/wntrblm/nox/
+	https://pypi.org/project/nox/
+"
+SRC_URI="
+	https://github.com/wntrblm/nox/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	<dev-python/argcomplete-3.0[${PYTHON_USEDEP}]
+	>=dev-python/argcomplete-1.9.4[${PYTHON_USEDEP}]
+	<dev-python/colorlog-7.0.0[${PYTHON_USEDEP}]
+	>=dev-python/colorlog-2.6.1[${PYTHON_USEDEP}]
+	>=dev-python/packaging-20.9[${PYTHON_USEDEP}]
+	>=dev-python/virtualenv-14[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# broken with >=dev-python/tox-4
+	# https://github.com/wntrblm/nox/issues/673
+	rm nox/tox_to_nox.* tests/test_tox_to_nox.py || die
+	sed -i -e '/tox-to-nox/d' pyproject.toml || die
+	distutils-r1_src_prepare
+}