From fe71f9c1ef4689559b4e661b95f0e7e30d78537d Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Wed, 12 Nov 2025 03:45:32 +0100
Subject: [PATCH] dev-python/pycairo: Bump to 1.29.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/pycairo/Manifest              |  1 +
 dev-python/pycairo/pycairo-1.29.0.ebuild | 64 ++++++++++++++++++++++++
 2 files changed, 65 insertions(+)
 create mode 100644 dev-python/pycairo/pycairo-1.29.0.ebuild

diff --git a/dev-python/pycairo/Manifest b/dev-python/pycairo/Manifest
index 774fd592ce84..f95d65ed4535 100644
--- a/dev-python/pycairo/Manifest
+++ b/dev-python/pycairo/Manifest
@@ -1 +1,2 @@
 DIST pycairo-1.28.0.tar.gz 662477 BLAKE2B 26ab0ab926bc209c33eeff2f7578d31ffce138111e923f6bc8e31a5e318f7ead9d0350ee5717e3774c65eb8ac9f3324ff0446c316469796dc866c3530ef2d0dc SHA512 d3fcb6641ad6dcf9b804dbc2a372f653619512e139fb7a196bb1219b00f60e79e5d60fbbddc2e6a0afb959f9fcb37f1f3c460ad6331274581cb241434865b5a5
+DIST pycairo-1.29.0.tar.gz 665871 BLAKE2B 25c2630923fd209bcdf21a3e0dce6ef5218c52eb5373bc6072174acfbb26c3dd908bc22308a3bf6b749216c10534ef79f2a7ad305c4f8eee694455e27b43e78f SHA512 c685fbdce764ca89e719ebcc8f966227a6c144c8e128945bf9c3411212a01759c016fd3267714328a5a242b37e3a5dd9aab4fc120193afdedb74596522a3cd2f
diff --git a/dev-python/pycairo/pycairo-1.29.0.ebuild b/dev-python/pycairo/pycairo-1.29.0.ebuild
new file mode 100644
index 000000000000..4354c52e47a0
--- /dev/null
+++ b/dev-python/pycairo/pycairo-1.29.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=meson-python
+# TODO: readd 3.13t & 3.14t (requires same in meson-python)
+PYTHON_COMPAT=( python3_{11..14} pypy3_11 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python bindings for the cairo library"
+HOMEPAGE="
+	https://www.cairographics.org/pycairo/
+	https://github.com/pygobject/pycairo/
+	https://pypi.org/project/pycairo/
+"
+SRC_URI="
+	https://github.com/pygobject/${PN}/releases/download/v${PV}/${P}.tar.gz
+"
+
+LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+IUSE="X examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=x11-libs/cairo-1.15.10[svg(+),X?]
+"
+DEPEND="
+	${RDEPEND}
+	x11-base/xorg-proto
+"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx-rtd-theme
+EPYTEST_PLUGINS=( hypothesis )
+distutils_enable_tests pytest
+
+src_configure() {
+	DISTUTILS_ARGS=(
+		-Dtests="$(usex test true false)"
+		-Dno-x11="$(usex X false true)"
+	)
+}
+
+python_test() {
+	rm -rf cairo || die
+	epytest
+}
+
+python_install_all() {
+	if use examples; then
+		dodoc -r examples
+	fi
+
+	distutils-r1_python_install_all
+}