gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2025-12-21 21:17:37 -08:00
Code Issues Projects Releases Wiki Activity

sys-boot/raspberrypi-firmware: add 1.20250915

Browse Source 
Closes: https://bugs.gentoo.org/952814
Closes: https://bugs.gentoo.org/912939
Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>
This commit is contained in:
Viorel Munteanu 2025-12-15 19:19:27 +02:00
parent 8fda46a0fe
commit fe6ad6b116
No known key found for this signature in database
GPG Key ID: 0CE5A97D9310DAB0
2 changed files with 74 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

1
sys-boot/raspberrypi-firmware/Manifest
View File

@ -1,3 +1,4 @@
DIST raspberrypi-firmware-1.20221104.tar.gz 184890613 BLAKE2B 51901015d10f7f06504a1cd4eaf50788065f78d806293e5cb40e930c926ad3f76688684b2333c87fd6528418372ac3b5f8f7ad32595a09d4f896717ebea51d29 SHA512 6662f3fdeffbf98819dd57d1c3d8571d7c8bd7d69a8eb5e38823e4ef2857ebfa4e550735f9488e10719a261a0cdcb99cb7f3fb765d674459d42737f4e2cfd357
DIST raspberrypi-firmware-1.20230106.tar.gz 185087907 BLAKE2B 656cc8325aa96d11f44419e871141beba95172b5c0c96e4b0a4cccca51127040328dc9f6c70cbba0248f8404ce0cf390e4bf937db7e0506c286db5adc4e56eef SHA512 41492a90da91d29e1025deeaad452c6b485f5412ff375b2fc144c2630afcdfef99ecbf701ca5e1afc5bb41bd6f2413b239257f1734dfe17084210e96b28eda7a
DIST raspberrypi-firmware-1.20240902.tar.gz 154483648 BLAKE2B e3d9fabb23246d90948004dde37f2125779a86aa62737b51b03cacea13d1ca715724587b0da106efba19c80a1bafcf1537101ce13ba4374602ca9e4957c81f87 SHA512 b5b1a74e1e9f9760fd19f98a35505b2e127e212c17afbdf08e1b92198f32de73655fb24c16d662318ccf50621ae5e1a6ed5aa877d2d1cc654d26b8ff168c1e82
DIST raspberrypi-firmware-1.20250915.tar.gz 163876502 BLAKE2B 2d994334f358043a9a7cd1a92f6a411bd8671043956ab6df5d200387522d7e8ddedf5b3ffaf25b2a482a6e7675029a6ccb40a64c43e3c65a8ef2770b465ebc03 SHA512 33120c901c59fbcd267427dce5fd8f174d32476bfae76744697f6729151d66054c6f0bd54f29c3b715c1492a52724fe2973a6adbf31cfb79f1c82dd94983cf77

73
sys-boot/raspberrypi-firmware/raspberrypi-firmware-1.20250915.ebuild Normal file
View File

@ -0,0 +1,73 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit mount-boot readme.gentoo-r1
if [[ "${PV}" == 9999 ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/raspberrypi/firmware"
EGIT_CLONE_TYPE="shallow"
else
SRC_URI="https://github.com/raspberrypi/firmware/archive/${PV}.tar.gz -> ${P}.tar.gz"
KEYWORDS="-* ~arm ~arm64"
S="${WORKDIR}/firmware-${PV}"
fi
DESCRIPTION="Raspberry Pi (all versions) bootloader and GPU firmware"
HOMEPAGE="https://github.com/raspberrypi/firmware"
LICENSE="raspberrypi-videocore-bin"
SLOT="0"
RESTRICT="strip"
QA_PREBUILT="*"
DOC_CONTENTS="Please configure your ram setup by editing /boot/config.txt"
src_prepare() {
default
cp "${FILESDIR}"/${PN}-1.20201022-config.txt "${WORKDIR}" || die
if use arm64; then
# Force selection of the 64-bit kernel8.img to match our userland
echo "arm_64bit=1" >> "${WORKDIR}"/${PN}-1.20201022-config.txt || die
fi
}
src_install() {
insinto /boot
cd boot || die
doins bootcode.bin fixup*.dat start*elf
newins "${WORKDIR}"/${PN}-1.20201022-config.txt config.txt
newins "${FILESDIR}"/${PN}-1.20201022-cmdline.txt cmdline.txt
newenvd "${FILESDIR}"/${PN}-0_p20130711-envd 90${PN}
readme.gentoo_create_doc
}
pkg_preinst() {
if [[ -z "${REPLACING_VERSIONS}" ]] ; then
local msg=""
if [[ -e "${ED}"/boot/cmdline.txt ]] && [[ -e /boot/cmdline.txt ]] ; then
msg+="/boot/cmdline.txt "
fi
if [[ -e "${ED}"/boot/config.txt ]] && [[ -e /boot/config.txt ]] ; then
msg+="/boot/config.txt "
fi
if [[ -n "${msg}" ]] ; then
msg="This package installs following files: ${msg}."
msg="${msg} Please remove (backup) your copies during install"
msg="${msg} and merge settings afterwards."
msg="${msg} Further updates will be CONFIG_PROTECTed."
die "${msg}"
fi
fi
}
pkg_postinst() {
readme.gentoo_print_elog
}