diff --git a/dev-util/colm/colm-0.14.7-r1.ebuild b/dev-util/colm/colm-0.14.7-r1.ebuild
new file mode 100644
index 0000000000000..831d5bc521f14
--- /dev/null
+++ b/dev-util/colm/colm-0.14.7-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="COmputer Language Manipulation"
+HOMEPAGE="https://www.colm.net/open-source/colm/"
+SRC_URI="https://www.colm.net/files/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="doc"
+
+BDEPEND="
+	doc? (
+		|| ( app-text/asciidoc dev-ruby/asciidoctor )
+		dev-python/pygments
+	)
+"
+# libfsm moved from ragel -> colm, bug #766108
+RDEPEND="!<dev-util/ragel-7.0.3"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.14.7-drop-julia-check.patch
+	"${FILESDIR}"/${PN}-0.14.7-disable-static-lib.patch
+)
+
+src_prepare() {
+	default
+
+	# bug #733426
+	sed -i -e 's/(\[ASCIIDOC\], \[asciidoc\], \[asciidoc\]/S([ASCIIDOC], [asciidoc asciidoctor]/' configure.ac || die
+
+	# bug #766069
+	sed -i -e "s:gcc:$(tc-getCC):" test/colm.d/gentests.sh || die
+	sed -i -e "s:g++:$(tc-getCXX):" test/colm.d/gentests.sh || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_enable doc manual)
+}
+
+src_test() {
+	# Build tests
+	default
+
+	# Run them
+	cd test || die
+	./runtests || die
+}
diff --git a/dev-util/colm/files/colm-0.14.7-disable-static-lib.patch b/dev-util/colm/files/colm-0.14.7-disable-static-lib.patch
new file mode 100644
index 0000000000000..53555e76d5d25
--- /dev/null
+++ b/dev-util/colm/files/colm-0.14.7-disable-static-lib.patch
@@ -0,0 +1,17 @@
+From: Ferdinand Thiessen <rpm@fthiessen.de>
+Date: 2021-04-26T19:48:55+0000
+
+Link shared library as the static one is disabled in the openSUSE build.
+
+diff -Nur colm-0.14.7/src/main.cc new/src/main.cc
+--- colm-0.14.7/src/main.cc	2020-12-24 00:37:24.000000000 +0100
++++ new/src/main.cc	2021-04-26 17:51:25.913611725 +0200
+@@ -485,7 +485,7 @@
+ 				" -I%s/../aapl"
+ 				" -I%s/include"
+ 				" -L%s"
+-				" %s/libcolm.a",
++				" %s/libcolm.so",
+ 				binaryFn, intermedFn, srcLocation,
+ 				srcLocation, location, location );
+ 	}