diff --git a/dev-python/spyder-kernels/Manifest b/dev-python/spyder-kernels/Manifest
index a3cbe2ea28c6d..696cf1ed2fe04 100644
--- a/dev-python/spyder-kernels/Manifest
+++ b/dev-python/spyder-kernels/Manifest
@@ -1,2 +1,3 @@
+DIST spyder-kernels-3.0.1.gh.tar.gz 238107 BLAKE2B bf2b67555b561e935e13cc8bedfe178396f100252f3a0a2f8606971691c62d2bba64fc2cae443654aadd3a853674184eaaa3567855ce1c1358f5142f40c5ca74 SHA512 a16fe124f4abf36bc95f2e409391c550063f5fc00024c3b58b635eb03ca449678065daa25c27c42a4a85babd6fcbf80ab6423e519221c3916c8ddbb03c0056b3
 DIST spyder_kernels-2.5.2.tar.gz 99972 BLAKE2B 178f175fe03fd2b7871681ae30d10b62a4daf9ee606477eab4f88a4d81d2692b80cdcf4f9b6d46c4cfc0394b98d798e93dda870a3f1cbe6f77e243fd2b06d97c SHA512 4cf5462d6a6e72bf13f9890fbc5a4008788e132ee3315b0ad01a00beff6b78c63f47b7b5d19be601b64984196cc1a5c4706a4c5bbe878d938e487ae9ddd9f1fc
 DIST spyder_kernels-3.0.0.tar.gz 242868 BLAKE2B 7cf667ce42d9f0a1c6b0df337c98a702588c546eeedfeb8150cea560c7ba5f0049ccb76f1342584f7a6cf9bf400ed2d1dbbad12f5b39ae3a3343e3449aed3414 SHA512 42c176d6c8c410b375342c2fed07dd5ff6440e857dac06097d55c1f3d34bed6d51873833523b798316f100d3f226f78cf76d661a30c7e968683eaad622d5c994
diff --git a/dev-python/spyder-kernels/spyder-kernels-3.0.1.ebuild b/dev-python/spyder-kernels/spyder-kernels-3.0.1.ebuild
new file mode 100644
index 0000000000000..8de6a2b905d8b
--- /dev/null
+++ b/dev-python/spyder-kernels/spyder-kernels-3.0.1.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{10..13} )
+
+inherit distutils-r1
+
+DESCRIPTION="Kernels used by spyder on its ipython console"
+HOMEPAGE="
+	https://github.com/spyder-ide/spyder-kernels/
+	https://pypi.org/project/spyder-kernels/
+"
+SRC_URI="https://github.com/spyder-ide/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/cloudpickle[${PYTHON_USEDEP}]
+	<dev-python/ipykernel-7[${PYTHON_USEDEP}]
+	>=dev-python/ipykernel-6.29.3[${PYTHON_USEDEP}]
+	<dev-python/ipython-9[${PYTHON_USEDEP}]
+	>dev-python/ipython-8.13.0[${PYTHON_USEDEP}]
+	<dev-python/jupyter-client-9[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-client-7.4.9[${PYTHON_USEDEP}]
+	dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+	>=dev-python/pyxdg-0.26[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-24.0.0[${PYTHON_USEDEP}]
+	>=dev-python/wurlitzer-1.0.3[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		dev-python/cython[${PYTHON_USEDEP}]
+		dev-python/django[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/h5py[${PYTHON_USEDEP}]
+			dev-python/pandas[${PYTHON_USEDEP}]
+			dev-python/xarray[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# we no longer package distributed, and also removed dependency on dask
+		spyder_kernels/console/tests/test_console_kernel.py::test_dask_multiprocessing
+
+		# RuntimeError: There is no current event loop in thread 'MainThread'.
+		# https://bugs.gentoo.org/834893
+		spyder_kernels/console/tests/test_console_kernel.py::test_cwd_in_sys_path
+		spyder_kernels/console/tests/test_console_kernel.py::test_multiprocessing
+		spyder_kernels/console/tests/test_console_kernel.py::test_multiprocessing_2
+		spyder_kernels/console/tests/test_console_kernel.py::test_runfile
+		spyder_kernels/console/tests/test_console_kernel.py::test_np_threshold
+		spyder_kernels/console/tests/test_console_kernel.py::test_turtle_launch
+		spyder_kernels/console/tests/test_console_kernel.py::test_matplotlib_inline
+
+		# pydicom only packaged in ::sci at the moment
+		spyder_kernels/utils/tests/test_iofuncs.py::test_load_dicom_files
+	)
+	local EPYTEST_IGNORE=()
+
+	if ! has_version "dev-python/pandas[${PYTHON_USEDEP}]"; then
+		EPYTEST_IGNORE+=(
+			# require pandas
+			spyder_kernels/utils/tests/test_nsview.py
+		)
+	fi
+
+	if ! has_version "dev-python/h5py[${PYTHON_USEDEP}]"; then
+		EPYTEST_DESELECT+=(
+			# require hdf5
+			spyder_kernels/utils/tests/test_iofuncs.py::test_save_load_hdf5_files
+			spyder_kernels/utils/tests/test_dochelpers.py
+		)
+	fi
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}