x11-drivers/xf86-input-wacom: version bump to 0.35.0

Package-Manager: Portage-2.3.6, Repoman-2.3.1

x11-drivers/xf86-input-wacom/Manifest

@@ -1 +1,2 @@
 DIST xf86-input-wacom-0.34.0.tar.bz2 598624 SHA256 f15d8e4f3bf3a5b2db0b3f9c9565361b084896c3cb54ac11b8de5e405f9cb045 SHA512 d0aae70853f73d989d168e054bb21ddbd2114ec6c012b1c5f949838bb20a7fe75711211886dd649ec0e9449d199da17b4ff156d5d672ad02c8b2e0b667cc40ad WHIRLPOOL f45ac8e8c93ac343cc8002ae0a981483ba5fda9aa975b935a423e86c42297c54fbff50e44a0c58c915fc3d49aa06bb743684cdc357c90678c9ef2ee332a7f94f
+DIST xf86-input-wacom-0.35.0.tar.bz2 601314 SHA256 55f60a71e81ef5544885652069a4f52b5cbaceabba53a28ac1397ec0ac26447d SHA512 9586348e8da91651bc9a9ee9e74dd77f4311060538dcb228681b98300f7624401878190322dcbc4e798bd1eeeb7d2900abc3f5e949a583b6cda44821b8821058 WHIRLPOOL 8901ec1807b8cb15a440c64500bc6c0161ad3397bbc033fa9e46a4532f51a2b29028aec663603704cb9783671c35efb43f9ceb4969afac7db362274379d3a022

x11-drivers/xf86-input-wacom/xf86-input-wacom-0.35.0.ebuild

@@ -0,0 +1,73 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+inherit linux-info xorg-2
+
+DESCRIPTION="Driver for Wacom tablets and drawing devices"
+HOMEPAGE="http://linuxwacom.sourceforge.net/"
+LICENSE="GPL-2"
+EGIT_REPO_URI="git://git.code.sf.net/p/linuxwacom/${PN}"
+[[ ${PV} != 9999* ]] && \
+	SRC_URI="mirror://sourceforge/linuxwacom/${PN}/${P}.tar.bz2"
+
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="debug"
+
+# depend on libwacom for its udev rules, bug #389633
+RDEPEND="dev-libs/libwacom
+	virtual/udev
+	>=x11-base/xorg-server-1.7
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXi
+	x11-libs/libXrandr
+	x11-libs/libXinerama"
+DEPEND="${RDEPEND}
+	x11-proto/randrproto"
+
+pkg_setup() {
+	linux-info_pkg_setup
+
+	XORG_CONFIGURE_OPTIONS=(
+		$(use_enable debug)
+	)
+}
+
+src_install() {
+	xorg-2_src_install
+
+	rm -rf "${ED}"/usr/share/hal
+}
+
+pkg_pretend() {
+	linux-info_pkg_setup
+
+	if kernel_is lt 3 17; then
+		if ! linux_config_exists \
+				|| ! linux_chkconfig_present TABLET_USB_WACOM \
+				|| ! linux_chkconfig_present INPUT_EVDEV; then
+			echo
+			ewarn "If you use a USB Wacom tablet, you need to enable support in your kernel"
+			ewarn "  Device Drivers --->"
+			ewarn "    Input device support --->"
+			ewarn "      <*>   Event interface"
+			ewarn "      [*]   Tablets  --->"
+			ewarn "        <*>   Wacom Intuos/Graphire tablet support (USB)"
+			echo
+		fi
+	else
+		if ! linux_config_exists \
+				|| ! linux_chkconfig_present HID_WACOM; then
+			echo
+			ewarn "If you use a USB Wacom tablet, you need to enable support in your kernel"
+			ewarn "  Device Drivers --->"
+			ewarn "    HID support  --->"
+			ewarn "      Special HID drivers  --->"
+			ewarn "        <*> Wacom Intuos/Graphire tablet support (USB)"
+			echo
+		fi
+	fi
+
+}