diff --git a/dev-scheme/akku/akku-1.1.0-r100.ebuild b/dev-scheme/akku/akku-1.1.0-r100.ebuild
new file mode 100644
index 0000000000000..f34a1d8afdf70
--- /dev/null
+++ b/dev-scheme/akku/akku-1.1.0-r100.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+GUILE_COMPAT=( 2-2 3-0 )
+inherit autotools guile
+
+DESCRIPTION="Language package manager for Scheme"
+HOMEPAGE="https://akkuscm.org/"
+
+if [[ "${PV}" == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.com/akkuscm/${PN}.git"
+else
+	SRC_URI="https://gitlab.com/akkuscm/${PN}/-/archive/v${PV}/${PN}-v${PV}.tar.gz"
+	KEYWORDS="~amd64"
+	S="${WORKDIR}/${PN}-v${PV}"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+
+REQUIRED_USE="${GUILE_REQUIRED_USE}"
+
+# tests require network access
+RESTRICT="test"
+
+RDEPEND="
+	${GUILE_DEPS}
+	net-misc/curl[ssl]
+"
+DEPEND="${RDEPEND}"
+
+# Installs into its own path
+# https://gitlab.com/akkuscm/akku/-/commit/d25da297fec2a2b16427359a2cbb0ec745dd8c58
+QA_PREBUILT="usr/*/${PN}/guile/*/site-ccache/*"
+
+src_prepare() {
+	guile_src_prepare
+
+	eautoreconf
+}
+
+src_compile() {
+	touch bootstrap.db || die
+
+	guile_src_compile
+}
diff --git a/profiles/package.mask b/profiles/package.mask
index 9b2e8c4c1718e..e665148184031 100644
--- a/profiles/package.mask
+++ b/profiles/package.mask
@@ -360,6 +360,7 @@ dev-scheme/guile:3.0
 >=app-shells/gash-0.3.0-r100
 >=dev-build/remake-4.3.1.1.6-r100
 >=dev-debug/gdb-15.1-r100
+>=dev-scheme/akku-1.1.0-r100
 
 # Eli Schwartz <eschwartz@gentoo.org> (2024-08-15)
 # Abandoned upstream since 2011, unmaintained in gentoo since 2017. Tons of