diff --git a/dev-python/tree-sitter/Manifest b/dev-python/tree-sitter/Manifest
index 7c1d209124cac..d3329791d7e06 100644
--- a/dev-python/tree-sitter/Manifest
+++ b/dev-python/tree-sitter/Manifest
@@ -1,2 +1,3 @@
 DIST tree-sitter-0.24.0.gh.tar.gz 170141 BLAKE2B 3d7f076f947192105be2fc9d93831eb331c1ec189619f6db860db8b6b6c1f2f33cd03edf315c09a5de6637d870351d06d5507d9c0de8a4dadc4e9e863ac233e8 SHA512 471d605cc29bcf7fd228eefe8a3bc2dd39c163d584e941cfd8ac0e498ff1815c7cadb9a7a45c643f704b8c9f12932bcc53597c835e23b5988da087f9a6a59067
 DIST tree-sitter-0.25.1.gh.tar.gz 174288 BLAKE2B 2580e7909e28ea05dfe8a015eb0e26d465318a0962666dc8de3d82d80c7647a62398abee093ccea13a04119e685dac3365ed098a70f7c50fac383cef34f7cb62 SHA512 37a6035921d44a13ef2128c8ff5dd7d8424dd50c1b5089a143ecfd921848304d91339d17108fa9e2f7ea0a6755b03413061ed6a6561ef1d8473534e8cf4636ef
+DIST tree-sitter-0.25.2.gh.tar.gz 174357 BLAKE2B c136098245beff521e7bf26b58b0cb4adfcfbec05ad59f62949c422c414cd879a973390875c285b014593790a5fb243863cc2b82dbecbf3297f24b394b06350a SHA512 ee0ee294cd3380442bb6f4f62413590818bfa4afbde1601bb89c777e97dcee885a22a06e529913c2fb08d082f5de775ced9403ffd5d2ca35dcfd0b19072ee452
diff --git a/dev-python/tree-sitter/tree-sitter-0.25.2.ebuild b/dev-python/tree-sitter/tree-sitter-0.25.2.ebuild
new file mode 100644
index 0000000000000..0a78ecfd47375
--- /dev/null
+++ b/dev-python/tree-sitter/tree-sitter-0.25.2.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python bindings to the Tree-sitter parsing library"
+HOMEPAGE="
+	https://github.com/tree-sitter/py-tree-sitter/
+	https://pypi.org/project/tree-sitter/
+"
+SRC_URI="
+	https://github.com/tree-sitter/py-tree-sitter/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S=${WORKDIR}/py-${P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+# setuptools is needed for distutils import
+DEPEND="=dev-libs/tree-sitter-0.25*:="
+RDEPEND="${DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/setuptools[${PYTHON_USEDEP}]
+	' 3.12 3.13)
+"
+BDEPEND="
+	test? (
+		>=dev-libs/tree-sitter-html-0.23.2[python,${PYTHON_USEDEP}]
+		>=dev-libs/tree-sitter-javascript-0.23.1[python,${PYTHON_USEDEP}]
+		>=dev-libs/tree-sitter-json-0.24.8[python,${PYTHON_USEDEP}]
+		>=dev-libs/tree-sitter-python-0.23.6[python,${PYTHON_USEDEP}]
+		>=dev-libs/tree-sitter-rust-0.23.2[python,${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.22.2-unbundle.patch
+)
+
+src_unpack() {
+	default
+	rmdir "${S}/tree_sitter/core" || die
+}
+
+src_test() {
+	rm -r tree_sitter || die
+	distutils-r1_src_test
+}