dev-python/tables: Bump to 3.10.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/tables/Manifest

@@ -1 +1,2 @@
 DIST tables-3.10.1.tar.gz 4762413 BLAKE2B b185e839767cb339bf5e3760d6d37593eb57551776c563bd99eaaeabc5ee3c041f3b86a03995294dbfaa1a27b0581b0c4544fac0dbdfacd507fe487c1256a2cc SHA512 7590dccefdd718d170ac288d391173ed540760a911f53fd39e37dd74237dc554f9363c8d9d4d518f067da299d71a1d8cb4a40134b1afaf79daa0a17de248caf5
+DIST tables-3.10.2.tar.gz 4779722 BLAKE2B 3242a1a4ec167f5f21496e8602fcf319fa387ad9245955d17c74605cec97a6222f92197ad7c2f7d3d53fa72740c5bfe9c0c759500698999e3fa5aea036e6ff7e SHA512 c2a1781113d31b35a75a2ce34fe0e922824340efd3077df419913ec6bdb4b0a59ee0601736423c34baf9d61aa0a7122f0b0440e4000cfe61a6dde5f369574450

dev-python/tables/tables-3.10.2.ebuild

@@ -0,0 +1,75 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{10..13} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 prefix pypi
+
+DESCRIPTION="Hierarchical datasets for Python"
+HOMEPAGE="
+	https://www.pytables.org/
+	https://github.com/PyTables/PyTables/
+	https://pypi.org/project/tables/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="+cpudetection examples test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	app-arch/bzip2:0=
+	app-arch/lz4:0=
+	>=app-arch/zstd-1.0.0:=
+	>=dev-libs/c-blosc-1.11.1:0=
+	>=dev-libs/c-blosc2-2.11.0:=
+	dev-libs/lzo:2=
+	>=dev-python/numpy-1.19.0:=[${PYTHON_USEDEP}]
+	>=sci-libs/hdf5-1.8.4:=
+"
+RDEPEND="
+	${DEPEND}
+	>=dev-python/numexpr-2.6.2[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	cpudetection? ( dev-python/py-cpuinfo[${PYTHON_USEDEP}] )
+"
+BDEPEND="
+	>=dev-python/cython-3.0.10[${PYTHON_USEDEP}]
+	virtual/pkgconfig
+	cpudetection? ( dev-python/py-cpuinfo[${PYTHON_USEDEP}] )
+	test? (
+		${RDEPEND}
+	)
+"
+
+python_prepare_all() {
+	rm -r c-blosc/{blosc,internal-complibs} || die
+
+	distutils-r1_python_prepare_all
+
+	sed -i -e '/blosc2/d' pyproject.toml || die
+	hprefixify -w '/prefixes =/' setup.py
+
+	export PYTABLES_NO_EMBEDDED_LIBS=1
+	export USE_PKGCONFIG=TRUE
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	"${EPYTHON}" tables/tests/test_all.py -v || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		dodoc -r contrib examples
+		docompress -x /usr/share/doc/${PF}/{contrib,examples}
+	fi
+}