dev-python/h5py: Bump to 3.15.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/h5py/Manifest

@@ -1 +1,2 @@
 DIST h5py-3.14.0.tar.gz 424323 BLAKE2B 4e8a2f78859aa4a9647a06f9319e79bc7f46d35029c02f7814d6c72fd2211c1d4c0cecdd7c14c3afc77a507e0bf98ef78009b2716f2d9cdbb152dd1578677088 SHA512 54e0054a542c8b62da90e15c110a153cc0cadc6cba1914074d35a6380f8b270ba051de860feb7e31c2ee3d4f09903e456c94e9faa3570764af0e36c480e1c44e
+DIST h5py-3.15.0.tar.gz 425986 BLAKE2B f591276161d8c48e66c0678dd4bee88303816b21059c6a83540a69ae4c7890cf02f0dd3a1f81fc168339531319b014a7e24e33d5fc079b57bce401be7a085bbd SHA512 76a382bcfd5805e1a72a3770f1bf60851786642c7cad69021b02f850453e740ab26cd6de032ab0759113b9d2ad6e79f38492779c9acf83491123561dac9d2c6d

dev-python/h5py/h5py-3.15.0.ebuild

@@ -0,0 +1,63 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Simple Python interface to HDF5 files"
+HOMEPAGE="
+	https://www.h5py.org/
+	https://github.com/h5py/h5py/
+	https://pypi.org/project/h5py/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~x64-macos"
+IUSE="examples"
+
+DEPEND="
+	>=dev-python/numpy-1.21.2:=[${PYTHON_USEDEP}]
+	>=sci-libs/hdf5-1.10.4:=[hl(+)]
+"
+RDEPEND="
+	${DEPEND}
+"
+
+BDEPEND="
+	>=dev-python/cython-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.14.5[${PYTHON_USEDEP}]
+	>=dev-python/pkgconfig-1.5.5[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-77.0.1[${PYTHON_USEDEP}]
+	test? (
+		dev-python/qtpy[testlib,${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	dev-python/sphinx-rtd-theme
+
+python_prepare_all() {
+	# avoid pytest-mpi dep, we do not use mpi anyway
+	sed -i -e 's:pytest-mpi::' pytest.ini || die
+	distutils-r1_python_prepare_all
+
+	export H5PY_SETUP_REQUIRES=0
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	epytest -m "not mpi"
+}
+
+python_install_all() {
+	use examples && dodoc -r examples
+	distutils-r1_python_install_all
+}