From fa859af2971199575c43b5e9c55469496a4e750a Mon Sep 17 00:00:00 2001
From: Yixun Lan <dlan@gentoo.org>
Date: Mon, 23 Feb 2026 19:45:56 +0800
Subject: [PATCH] sys-apps/tuned: add 2.27.0

Signed-off-by: Yixun Lan <dlan@gentoo.org>
---
 sys-apps/tuned/Manifest            |  1 +
 sys-apps/tuned/tuned-2.27.0.ebuild | 78 ++++++++++++++++++++++++++++++
 2 files changed, 79 insertions(+)
 create mode 100644 sys-apps/tuned/tuned-2.27.0.ebuild

diff --git a/sys-apps/tuned/Manifest b/sys-apps/tuned/Manifest
index d26a77485882c..97b86b585fdf3 100644
--- a/sys-apps/tuned/Manifest
+++ b/sys-apps/tuned/Manifest
@@ -1,2 +1,3 @@
 DIST tuned-2.25.1.tar.gz 268726 BLAKE2B 324f47f7a45bb363fb171ceed3139da3a7f2b16fecda061ac1183b58c09c9787dff50d2092b21d3e0c8a2c259cecbd8f501ff6de284837f47b49c2deb89b4185 SHA512 fa5ac9d818d11b118fb7c26db28993b704f590070edbece570fee1a6c60a1f5f850b711683c45b46f33d9b056a84e43ced2c4c1ee58e9ef3d1fd035a4c1d4de4
 DIST tuned-2.26.0.tar.gz 271590 BLAKE2B a139ed7999f0927b16aaf4aca169483f3e20f373d4bafb8d622b0828c0130a2a4e6023a077b786a5dc1f395b368b58c013cfa1c01985de087808ee33ba6657d8 SHA512 af468e1b4ca2e10cf00cad53f27d65d0b5eab73e65b9c61d67fd39ff9687700704db87294fbf62bda949b3544a9ba69c82f6d35f448226654a5949fa8de1b2c0
+DIST tuned-2.27.0.tar.gz 272697 BLAKE2B 574d79cdd69ee27ed409a23b2b25b7972d2b479786177f046c9e7b67a3835c1a1a9e9228ca5ebddca8dffc08bd74dbbc368d71c6e37dc11f412a1c7e5c238192 SHA512 7471d073879a688da66e72c4f5c562d1a732d6bfb562d8c033874a8edbad2bab3cf3c7dc387270bf99ae6b1b35ffc451173122e32023116709567e529e09dc52
diff --git a/sys-apps/tuned/tuned-2.27.0.ebuild b/sys-apps/tuned/tuned-2.27.0.ebuild
new file mode 100644
index 0000000000000..078d8c90eb931
--- /dev/null
+++ b/sys-apps/tuned/tuned-2.27.0.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit optfeature python-single-r1 tmpfiles xdg-utils
+
+DESCRIPTION="Daemon for monitoring and adaptive tuning of system devices"
+HOMEPAGE="https://github.com/redhat-performance/tuned"
+SRC_URI="https://github.com/redhat-performance/tuned/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+ppd"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="
+	${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		dev-python/configobj[${PYTHON_USEDEP}]
+		dev-python/dbus-python[${PYTHON_USEDEP}]
+		dev-python/decorator[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/python-linux-procfs[${PYTHON_USEDEP}]
+		dev-python/pyudev[${PYTHON_USEDEP}]
+	')
+	ppd? (
+		$(python_gen_cond_dep '
+			dev-python/pyinotify[${PYTHON_USEDEP}]
+		')
+	)"
+
+RDEPEND="
+	${DEPEND}
+	app-emulation/virt-what
+	dev-debug/systemtap
+	sys-apps/dbus
+	sys-apps/ethtool
+	sys-power/powertop
+	ppd? ( !sys-power/power-profiles-daemon )
+	"
+
+RESTRICT="test"
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "/^PYTHON/s:/usr/bin/python3:${EPREFIX}/usr/bin/${EPYTHON}:" \
+		-e "/^export DOCDIR/s/$/&\-\$(VERSION)/g" \
+		-e "/\$(DESTDIR)\/run\/tuned/d" \
+		-e "/\$(DESTDIR)\/var\/lib\/tuned/d" \
+		-e "/\$(DESTDIR)\/var\/log\/tuned/d" \
+		Makefile || die
+}
+
+src_install() {
+	default
+	use ppd && emake DESTDIR="${ED}" install-ppd
+
+	newinitd "${FILESDIR}/${PN}.initd" "${PN}"
+	python_fix_shebang "${D}"
+	python_optimize
+}
+
+pkg_postinst() {
+	tmpfiles_process ${PN}.conf
+	xdg_icon_cache_update
+
+	optfeature_header
+	optfeature "Optimize for power saving by spinning-down rotational disks" sys-apps/hdparm
+	optfeature "Get hardware info" sys-apps/dmidecode
+	optfeature "Optimize network txqueuelen" sys-apps/iproute2
+}