dev-java/bcpg: add 1.77

Signed-off-by: Volkmar W. Pogatzki <gentoo@pogatzki.net>
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

dev-java/bcpg/Manifest

@@ -1 +1,2 @@
 DIST bc-java-r1rv76.tar.gz 31256952 BLAKE2B b791ef3da7189bc6990935aaad7c331c1bf6a45af0cdfc72056ae0cf1723e57ce15a76060251f6de630b0729ffe22ba4718255c103a8ab66db61f2e46f1201c8 SHA512 7d408821408bbabd209d9507b061f3113822878c12b12a040c829f5a8c6bdf8450719aef60c423025824bec1fcb6c63d8478d1f84f3cb1d692fdbacde6d9ce6e
+DIST bc-java-r1rv77.tar.gz 31402744 BLAKE2B 1ca1e1dac1ed3d613ae66f08cd8a954e63d43a49ed402f5bd7c30cf1f0830ad29104aa91a9a0a3cbbb5ea750392bc285172a1ab38f2aba1600fa3ca4c469b4f5 SHA512 d75a0ce94bd006499eef9393491347ae70544643c93c2f7591df3ff0179bd477a5066891c7c3bdeb09bd693093c9dc7d29c48462a1d539e464cbf2ee9c1dfce4

dev-java/bcpg/bcpg-1.77.ebuild

@@ -0,0 +1,60 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+JAVA_PKG_IUSE="doc source test"
+MAVEN_ID="org.bouncycastle:bcpg-jdk18on:${PV}"
+JAVA_TESTING_FRAMEWORKS="junit-4"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="Java cryptography APIs"
+HOMEPAGE="https://www.bouncycastle.org/java.html"
+MY_PV="r${PV/./rv}"
+SRC_URI="https://github.com/bcgit/bc-java/archive/${MY_PV}.tar.gz -> bc-java-${MY_PV}.tar.gz"
+S="${WORKDIR}/bc-java-${MY_PV}/pg"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+
+CP_DEPEND="~dev-java/bcprov-${PV}:0"
+DEPEND="${CP_DEPEND}
+	>=virtual/jdk-11:*"
+RDEPEND="${CP_DEPEND}
+	>=virtual/jre-1.8:*"
+
+DOCS=( ../{README,SECURITY}.md )
+HTML_DOCS=( ../{CONTRIBUTORS,index}.html )
+
+JAVA_SRC_DIR=(
+	"src/main/java"
+	"src/main/jdk1.9"
+)
+
+JAVA_AUTOMATIC_MODULE_NAME="org.bouncycastle.pg"
+JAVA_TEST_GENTOO_CLASSPATH="junit-4"
+JAVA_TEST_RESOURCE_DIRS="src/test/resources"
+JAVA_TEST_SRC_DIR="src/test/java"
+
+src_prepare() {
+	java-pkg-2_src_prepare
+	java-pkg_clean ..
+}
+
+src_test() {
+	pushd src/test/java || die
+		local JAVA_TEST_RUN_ONLY=$(find * \
+			-name "AllTests.java" )
+	popd || die
+	JAVA_TEST_RUN_ONLY="${JAVA_TEST_RUN_ONLY//.java}"
+	JAVA_TEST_RUN_ONLY="${JAVA_TEST_RUN_ONLY//\//.}"
+	java-pkg-simple_src_test
+}
+
+src_install() {
+	docinto html
+	dodoc -r ../docs
+	java-pkg-simple_src_install
+}