From f7f450f5670c673a0cb332f876d9dea110c0b9dc Mon Sep 17 00:00:00 2001
From: Sebastian Pipping <sping@gentoo.org>
Date: Fri, 28 Mar 2025 18:27:41 +0100
Subject: [PATCH] sys-fs/unionfs-fuse: Python 3.13

Closes: https://bugs.gentoo.org/952738
Signed-off-by: Sebastian Pipping <sping@gentoo.org>
---
 .../unionfs-fuse/unionfs-fuse-3.6-r2.ebuild   | 48 +++++++++++++++++++
 sys-fs/unionfs-fuse/unionfs-fuse-9999.ebuild  |  2 +-
 2 files changed, 49 insertions(+), 1 deletion(-)
 create mode 100644 sys-fs/unionfs-fuse/unionfs-fuse-3.6-r2.ebuild

diff --git a/sys-fs/unionfs-fuse/unionfs-fuse-3.6-r2.ebuild b/sys-fs/unionfs-fuse/unionfs-fuse-3.6-r2.ebuild
new file mode 100644
index 0000000000000..edbaab363381b
--- /dev/null
+++ b/sys-fs/unionfs-fuse/unionfs-fuse-3.6-r2.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+
+PYTHON_COMPAT=( python3_{9..13} )
+inherit python-any-r1 toolchain-funcs
+
+DESCRIPTION="Self-syncing tree-merging file system based on FUSE"
+HOMEPAGE="https://github.com/rpodgorny/unionfs-fuse"
+SRC_URI="https://github.com/rpodgorny/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-linux"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="sys-fs/fuse:3="
+DEPEND="${RDEPEND}"
+BDEPEND="
+	test? (
+		$(python_gen_any_dep 'dev-python/pytest[${PYTHON_USEDEP}]')
+	)
+"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+python_check_deps() {
+	use test || return 0
+	python_has_version "dev-python/pytest[${PYTHON_USEDEP}]"
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)" CC="$(tc-getCC)"
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" install
+}
+
+src_test() {
+	[[ -e /dev/fuse ]] || return 0
+	addwrite /dev/fuse
+	pytest -vv || die "Tests fail with ${EPYTHON}"
+}
diff --git a/sys-fs/unionfs-fuse/unionfs-fuse-9999.ebuild b/sys-fs/unionfs-fuse/unionfs-fuse-9999.ebuild
index a1af3d5796f4d..64a5ee9a36352 100644
--- a/sys-fs/unionfs-fuse/unionfs-fuse-9999.ebuild
+++ b/sys-fs/unionfs-fuse/unionfs-fuse-9999.ebuild
@@ -3,7 +3,7 @@
 
 EAPI="8"
 
-PYTHON_COMPAT=( python3_{9..12} )
+PYTHON_COMPAT=( python3_{9..13} )
 inherit git-r3 python-any-r1 toolchain-funcs
 
 DESCRIPTION="Self-syncing tree-merging file system based on FUSE"