From f719c01ce477935f212cabbb30cc8b68a9f595e6 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Wed, 15 Jul 2020 12:11:26 +0200
Subject: [PATCH] dev-python/boto: Add missing test deps
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Closes: https://bugs.gentoo.org/732672
Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/boto/boto-2.49.0-r3.ebuild | 50 +++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 dev-python/boto/boto-2.49.0-r3.ebuild

diff --git a/dev-python/boto/boto-2.49.0-r3.ebuild b/dev-python/boto/boto-2.49.0-r3.ebuild
new file mode 100644
index 0000000000000..e1554753e6cf5
--- /dev/null
+++ b/dev-python/boto/boto-2.49.0-r3.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6..9} )
+DISTUTILS_USE_SETUPTOOLS=bdepend
+inherit distutils-r1
+
+DESCRIPTION="Amazon Web Services API"
+HOMEPAGE="https://github.com/boto/boto https://pypi.org/project/boto/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64 ~arm64 x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+
+PATCHES=(
+	# taken from https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=909545
+	"${FILESDIR}/boto-try-to-add-SNI-support-v2.patch"
+	"${FILESDIR}"/${P}-py38.patch
+)
+
+BDEPEND="
+	test? (
+		dev-python/httpretty[${PYTHON_USEDEP}]
+		dev-python/keyring[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/paramiko[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/rsa[${PYTHON_USEDEP}]
+		dev-python/selenium[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests nose
+
+src_prepare() {
+	# broken, not worth fixing
+	rm tests/unit/cloudfront/test_signed_urls.py || die
+	# fix tests
+	mkdir -p "${HOME}"/.ssh || die
+	: > "${HOME}"/.ssh/known_hosts || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	nosetests -v tests/unit ||
+		die "Tests fail with ${EPYTHON}"
+}