From f6cbae88e43b7f3da9e1754afced4d429643594e Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Sat, 21 Dec 2024 13:30:36 +0100
Subject: [PATCH] dev-python/pyopengl-accelerate: Remove old
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 .../pyopengl-accelerate-3.1.8.ebuild          | 63 -------------------
 1 file changed, 63 deletions(-)
 delete mode 100644 dev-python/pyopengl-accelerate/pyopengl-accelerate-3.1.8.ebuild

diff --git a/dev-python/pyopengl-accelerate/pyopengl-accelerate-3.1.8.ebuild b/dev-python/pyopengl-accelerate/pyopengl-accelerate-3.1.8.ebuild
deleted file mode 100644
index 3b324795fb9c9..0000000000000
--- a/dev-python/pyopengl-accelerate/pyopengl-accelerate-3.1.8.ebuild
+++ /dev/null
@@ -1,63 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_EXT=1
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{10..13} )
-
-inherit distutils-r1
-
-MY_P=pyopengl-release-${PV}
-DESCRIPTION="Accelerate module for PyOpenGL"
-HOMEPAGE="
-	https://pyopengl.sourceforge.net/
-	https://github.com/mcfletch/pyopengl/
-	https://pypi.org/project/PyOpenGL-accelerate/
-"
-SRC_URI="
-	https://github.com/mcfletch/pyopengl/archive/release-${PV}.tar.gz
-		-> ${MY_P}.gh.tar.gz
-"
-S=${WORKDIR}/${MY_P}/accelerate
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="amd64 x86 ~amd64-linux ~x86-linux"
-IUSE="numpy"
-
-DEPEND="
-	numpy? (
-		dev-python/numpy[${PYTHON_USEDEP}]
-	)
-"
-RDEPEND="
-	${DEPEND}
-	dev-python/pyopengl[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	dev-python/cython[${PYTHON_USEDEP}]
-"
-
-distutils_enable_tests pytest
-
-src_configure() {
-	rm src/*.c || die
-
-	if ! use numpy; then
-		cat > "${T}"/numpy.py <<-EOF || die
-			raise ImportError("building numpy extension disabled")
-		EOF
-	fi
-}
-
-python_compile() {
-	local -x PYTHONPATH=${T}:${PYTHONPATH}
-	distutils-r1_python_compile
-}
-
-python_test() {
-	cd "${T}" || die
-	epytest "${S}"/tests
-}