From f6c7b24d68722df3a8be8a74156a78d0846c8b27 Mon Sep 17 00:00:00 2001
From: Conrad Kostecki <conikost@gentoo.org>
Date: Wed, 9 Feb 2022 20:57:39 +0100
Subject: [PATCH] dev-libs/libhid: update EAPI 7 -> 8

Signed-off-by: Conrad Kostecki <conikost@gentoo.org>
---
 dev-libs/libhid/libhid-0.2.17-r1.ebuild | 61 +++++++++++++++++++++++++
 1 file changed, 61 insertions(+)
 create mode 100644 dev-libs/libhid/libhid-0.2.17-r1.ebuild

diff --git a/dev-libs/libhid/libhid-0.2.17-r1.ebuild b/dev-libs/libhid/libhid-0.2.17-r1.ebuild
new file mode 100644
index 0000000000000..908ad8e000088
--- /dev/null
+++ b/dev-libs/libhid/libhid-0.2.17-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Provides a generic and flexible way to access and interact with USB HID devices"
+HOMEPAGE="https://wiki.gentoo.org/wiki/No_homepage"
+SRC_URI="https://dev.gentoo.org/~conikost/files/${P}.tar.gz"
+
+LICENSE="GPL-2 GPL-2+"
+SLOT="0"
+KEYWORDS="amd64 ppc ppc64 x86"
+IUSE="doc"
+
+RDEPEND="virtual/libusb:0="
+
+DEPEND="${RDEPEND}"
+
+BDEPEND="
+	app-text/docbook-xsl-stylesheets
+	dev-libs/libxslt
+	doc? ( app-doc/doxygen )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-configure.patch
+	"${FILESDIR}"/${P}-man.patch
+)
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	export OS_LDFLAGS="${LDFLAGS}"
+
+	myeconfargs=(
+		"--disable-static"
+		"--disable-swig"
+		"--disable-warnings"
+		"--disable-werror"
+		"$(use_with doc doxygen)"
+	)
+
+	econf ${myeconfargs[@]}
+}
+
+src_install() {
+	default
+
+	if use doc; then
+		docinto html
+		dodoc -r doc/html/.
+	fi
+
+	find "${D}" -name '*.la' -type f -delete || die
+}