dev-lua/luaposix: drop 35.0-r103

Signed-off-by: Conrad Kostecki <conikost@gentoo.org>

dev-lua/luaposix/Manifest

@@ -1,2 +1 @@
-DIST luaposix-35.0.tar.gz 178091 BLAKE2B b2d2ca01f18f0e98b45008919fc886e05d2cad034c84e870900c33891dd5867d9bc7aa8deae06c3f3f0852db902c1e766e693162b32ed474eb710b379bf9e3ed SHA512 4bb61892b78d9e59418a9a6360b9f611fb9b5438b9261a2c6672f053a1b21dfd9a2060b8d2f0d3eac6185773cf84672c1769c081c4ab53d2ddae2232e4a9269b
 DIST luaposix-35.1.tar.gz 180002 BLAKE2B fc48ae91c31968cb92ea9818148f135e16e2bacac10265cbfa43539c34a934c4eb636417b820ce3b0b3724fecbf27a860c6b481749d339b009fc01b6f81e6277 SHA512 f2c36bf69c0d73b4a2c6ab0915f81473addce427c22e82e2d1c334016dec7fecb4365fc980fa6adb0de21ad1a60bc75b73f58579e8a423990ad2067c9ae37775

dev-lua/luaposix/luaposix-35.0-r103.ebuild

@@ -1,79 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-LUA_COMPAT=( lua5-{1..4} luajit )
-
-inherit lua toolchain-funcs
-
-DESCRIPTION="Bindings for POSIX APIs"
-HOMEPAGE="https://luaposix.github.io/luaposix/ https://github.com/luaposix/luaposix"
-SRC_URI="https://github.com/luaposix/luaposix/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-SLOT="0"
-LICENSE="MIT"
-KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
-
-IUSE="doc"
-REQUIRED_USE="${LUA_REQUIRED_USE}"
-
-# Requires specl, which is not in the tree yet
-RESTRICT="test"
-
-DEPEND="${LUA_DEPS}
-	virtual/libcrypt:=
-"
-RDEPEND="${DEPEND}
-	lua_targets_lua5-1? ( dev-lua/lua-bit32[lua_targets_lua5-1(-)] )
-	lua_targets_luajit? ( dev-lua/lua-bit32[lua_targets_luajit(-)] )
-"
-BDEPEND="virtual/pkgconfig"
-
-src_prepare() {
-	default
-
-	# Temporary fix for respect LDFLAGS (#739050)
-	# Fixed in luke 0.2.1
-	sed -i -e "s:c_module,libdirs:c_module,'\$LDFLAGS',libdirs:g" \
-		build-aux/luke || die
-
-	lua_copy_sources
-}
-
-lua_src_compile() {
-	pushd "${BUILD_DIR}" || die
-
-	# LDOC=true means disable ldoc update documentation
-	./build-aux/luke --verbose package="${PN}" version="${PV}" \
-		LDOC=true \
-		PREFIX="${ED}/usr" \
-		INST_LIBDIR="${ED}/$(lua_get_cmod_dir)" \
-		INST_LUADIR="${ED}/$(lua_get_lmod_dir)" \
-		LUA_INCDIR="${EPREFIX}/$(lua_get_include_dir)" \
-		CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}" CC="$(tc-getCC)" || die
-
-	popd || die
-}
-
-src_compile() {
-	lua_foreach_impl lua_src_compile
-}
-
-lua_src_install() {
-	pushd "${BUILD_DIR}" || die
-
-	./build-aux/luke install \
-		LDOC=true \
-		PREFIX="${ED}/usr" \
-		INST_LIBDIR="${ED}/$(lua_get_cmod_dir)" \
-		INST_LUADIR="${ED}/$(lua_get_lmod_dir)" \
-		|| die
-
-	popd || die
-}
-
-src_install() {
-	lua_foreach_impl lua_src_install
-	dodoc {NEWS,README}.md
-	use doc && dodoc -r doc
-}