x11-drivers/xf86-input-wacom: Version bump to 1.2.4

Signed-off-by: Matt Turner <mattst88@gentoo.org>

x11-drivers/xf86-input-wacom/Manifest

@@ -1 +1,2 @@
 DIST xf86-input-wacom-1.2.3.tar.bz2 674630 BLAKE2B a3556579d88ec2b35e60928c6429ef0a374afe6a1873e70fca655c31749cc749810b7e348f075a3d8459ec6278ba5d67c7754cfe58b4050e112a5eef2e26da0c SHA512 1419f0d3103025d2f5d0b88b74c29f9b7cb9eb4f05119f8a469384af12b2821653596ce5adac918d8875e622cfccbd47ea9c6fc43d28c72091b09ec674e22de9
+DIST xf86-input-wacom-1.2.4.tar.bz2 690677 BLAKE2B 305b94e9c0b4ee7e0d75ce02c7f377cb2a7dd3790fe1a9e772ab4e67814ef9035aeb5a23948ef642c487ebe265b4a10e8e76000ddd5f8f2a13eab3d011ffc5d0 SHA512 7c1b62566f3dadad632c730afc0dfd81bf2082514091e2f1af1f04bbbf2e1f96877d6a982d127079f40d08bf503305b8c5ce8f526ff4a7ee5d7b0dcab27329b0

x11-drivers/xf86-input-wacom/xf86-input-wacom-1.2.4.ebuild

@@ -0,0 +1,63 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit linux-info systemd udev xorg-3 meson
+
+DESCRIPTION="Driver for Wacom tablets and drawing devices"
+HOMEPAGE="https://linuxwacom.github.io/"
+SRC_URI="https://github.com/linuxwacom/${PN}/releases/download/${P}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXi
+	x11-libs/libXrandr
+	x11-libs/libXinerama
+	virtual/libudev:="
+DEPEND="${RDEPEND}"
+
+pkg_pretend() {
+	linux-info_pkg_setup
+
+	if ! linux_config_exists \
+			|| ! linux_chkconfig_present HID_WACOM; then
+		echo
+		ewarn "If you use a USB Wacom tablet, you need to enable support in your kernel"
+		ewarn "  Device Drivers --->"
+		ewarn "    HID support  --->"
+		ewarn "      Special HID drivers  --->"
+		ewarn "        <*> Wacom Intuos/Graphire tablet support (USB)"
+		echo
+	fi
+}
+
+pkg_setup() {
+	linux-info_pkg_setup
+}
+
+src_configure() {
+	xorg-3_flags_setup
+
+	local emesonargs=(
+		-Dsystemd-unit-dir="$(systemd_get_systemunitdir)"
+		-Dudev-rules-dir="$(get_udevdir)/rules.d"
+		$(meson_feature test unittests)
+		-Dwacom-gobject=disabled
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	udev_reload
+}
+
+pkg_postrm() {
+	udev_reload
+}