mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2025-12-21 21:17:37 -08:00
dev-python/scikit-image: Bump to 0.26.0
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
parent
0365c822d1
commit
f42523c5f0
@ -1,6 +1,8 @@
|
||||
DIST scikit-image-data-15735b54e85c02427f07c71e6456723495034805.tar.bz2 143900901 BLAKE2B c1352e76337250fe1a9d6e07f08b6c9b1e0aed922ab8e0a3a4a1ea175f593b3375522e59550d30a22d392c34fef26d638c007c2af3d991887e02e7c68e56ebbb SHA512 d113dd258b35be710d841f9900cfbfe7103d1190b042489de88dd504b56277edac9a98fed5517e57725c5292fe26528267a06ff313bf6500b669d872c4481146
|
||||
DIST scikit-image-data-5c090b56df3988d988ff97928e2ef2d2cbe38e1b.tar.bz2 156723295 BLAKE2B fb30104cfa823361f4306606b64b23c8aed349767c1bf86aa3ee8c17d3d593c2ffda7b2f0baabd1e856407d342fbbca9d485e897ec3c219b79dae2a059457604 SHA512 69107940bfcafc6e056192b718065d74fbaa7c5c9da78a2789cc55c24e51b6d4d936dded07c71dbb8dcedf409faa4e97bea3ae0f5c873c936767979102eedc3e
|
||||
DIST scikit_image-0.25.2.tar.gz 22693594 BLAKE2B 238b44c120c53c10d98fc79c9ccb81770297a16156ba2d4d52cfa4731252aa205698caac384b8569c4b52ed2eb0e61500facff00c238a3212ecd7ba9b86db3da SHA512 8977585f7695d10df52d243d9fafdba2e04b5f4d4fe698dd9353bdffc4de21ad61053f55a46ed6350d5de8f1cd7dab969d45b85613a0e5fdb0b28a84c72551a9
|
||||
DIST scikit_image-0.26.0.tar.gz 22729739 BLAKE2B 3c2b9c0a0de449e6ac41e9b7e4c26fd21a59402e6cf58280923bf5ea4e98cd8287371bb01e184626ac2948b24872d6f8865a6f566c1fc4a5880e4ef139ff0e46 SHA512 30df4fa366d6f9b936f62247734ea26992e6d9af60390cf4bb9d87665dcfb395d27b67a52bf1a89d01ed4fa8dd56357a199201feacd5181c7e7f363a2c898cc5
|
||||
DIST scikit_image-0.26.0.tar.gz.provenance 9692 BLAKE2B 299f3097d71aa3261de38b6fbf38db91bdad84e95ba09dca7aef754d925b6013fbf7d0cc0426883ce5d3d9df9058ad890cb4ec014b7fb6e383512f4d41aa48cc SHA512 8cf6fbc4afae139135707abfb7d77221d68318cfb9358c3119cea05fadf5d10064b1843a7e07010b4af67feb163962d67d9ecbb8f4fee907fdfe17ce14c8b57d
|
||||
DIST scikit_image-0.26.0rc1.tar.gz 22730546 BLAKE2B 63ef735b0cf49aec86d2f6c0953346f3087a750defd73541497a387d8ebb4cc70a5d8c316081e6fb8bdc2841bbda616064c6031cff512e9d3e63db066fa9ebd4 SHA512 d9e473ebf75b8c627dcfc9e92827e627703cdc5e3e2cde88c1cfce37c5b543dfd143622e1b1af7d1093bf1644d2e16c71c28ccd7a0af4b888186be35470dfee0
|
||||
DIST scikit_image-0.26.0rc1.tar.gz.provenance 9858 BLAKE2B 50c4ba11c523add5a91c082ff57bbe12369b3c46133df1c6f5b859cfae9f7edae26ca3ee6f0e9ef96e242bce3f6b15738fc4d0ae0f9f98c157043b8daba258c9 SHA512 90d651546f2577d0e0e0692b48e04326aab0a5c32ac78ee68002fad8bc4d5fb14423d4f5bd5a3c9dcf359132856e5842fc6eeb3955db3ad2c5a62a1edaa52cbf
|
||||
DIST scikit_image-0.26.0rc2.tar.gz 22730972 BLAKE2B 8bda6ce9039a80a51f6376014f24cce34a4b25c128ea86d45db50247a761dee25a82036ec2eadb4efb4a6a3f12622c4498707b382da5879f81c68fa6b29e7732 SHA512 f1cae6d85517629d4421a0e6dda7a574e2e809dd2f7a9ccffe5ae5db34e217fe6102569c5f6bdaa67bdb520a0656223d0f7d94c52c05d339a149736959bd6caa
|
||||
|
||||
103
dev-python/scikit-image/scikit-image-0.26.0.ebuild
Normal file
103
dev-python/scikit-image/scikit-image-0.26.0.ebuild
Normal file
@ -0,0 +1,103 @@
|
||||
# Copyright 1999-2025 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
DISTUTILS_USE_PEP517=meson-python
|
||||
DISTUTILS_EXT=1
|
||||
PYPI_VERIFY_REPO=https://github.com/scikit-image/scikit-image
|
||||
PYTHON_COMPAT=( python3_{11..13} )
|
||||
|
||||
inherit distutils-r1 optfeature pypi
|
||||
|
||||
# the package refers to blobs directly, use the newest commit to get
|
||||
# them all
|
||||
TEST_DATA_COMMIT=5c090b56df3988d988ff97928e2ef2d2cbe38e1b
|
||||
DESCRIPTION="Image processing routines for SciPy"
|
||||
HOMEPAGE="
|
||||
https://scikit-image.org/
|
||||
https://github.com/scikit-image/scikit-image/
|
||||
https://pypi.org/project/scikit-image/
|
||||
"
|
||||
SRC_URI+="
|
||||
test? (
|
||||
https://gitlab.com/scikit-image/data/-/archive/${TEST_DATA_COMMIT}/scikit-image-data-${TEST_DATA_COMMIT}.tar.bz2
|
||||
)
|
||||
"
|
||||
|
||||
LICENSE="BSD"
|
||||
SLOT="0"
|
||||
if [[ ${PV} != *_rc* ]]; then
|
||||
KEYWORDS="~amd64 ~arm64 ~x86"
|
||||
fi
|
||||
|
||||
RDEPEND="
|
||||
>=dev-python/imageio-2.36[${PYTHON_USEDEP}]
|
||||
>=dev-python/lazy-loader-0.4[${PYTHON_USEDEP}]
|
||||
>=dev-python/networkx-3.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/numpy-1.24[${PYTHON_USEDEP}]
|
||||
>=dev-python/pillow-10.1[${PYTHON_USEDEP}]
|
||||
>=dev-python/scipy-1.11.4[sparse(+),${PYTHON_USEDEP}]
|
||||
>=dev-python/tifffile-2022.8.12[${PYTHON_USEDEP}]
|
||||
"
|
||||
DEPEND="
|
||||
${RDEPEND}
|
||||
dev-python/pythran[${PYTHON_USEDEP}]
|
||||
"
|
||||
BDEPEND="
|
||||
>=dev-python/cython-3.0.4[${PYTHON_USEDEP}]
|
||||
dev-python/packaging[${PYTHON_USEDEP}]
|
||||
dev-python/pythran[${PYTHON_USEDEP}]
|
||||
"
|
||||
|
||||
# xdist does not work with this test suite
|
||||
EPYTEST_PLUGINS=( pytest-localserver )
|
||||
distutils_enable_tests pytest
|
||||
# There is a programmable error in your configuration file:
|
||||
#distutils_enable_sphinx doc/source dev-python/numpydoc dev-python/myst-parser
|
||||
|
||||
src_test() {
|
||||
# just useless formatter replacement
|
||||
rm tests/conftest.py || die
|
||||
|
||||
# for some reason, upstream refetches data that's already in the tarball
|
||||
# sigh
|
||||
mkdir -p "${HOME}/.cache/scikit-image" || die
|
||||
mv src/skimage "${HOME}/.cache/scikit-image/${PV/_/}" || die
|
||||
|
||||
# This is a true horror, sigh
|
||||
local cache_dir=${HOME}/.cache/scikit-image/${PV/_/}/data
|
||||
pushd "${WORKDIR}/data-${TEST_DATA_COMMIT}" >/dev/null || die
|
||||
cp Tests_besides_Equalize_Otsu/add18_entropy/rank_filters_tests_3d.npz \
|
||||
Tests_besides_Equalize_Otsu/gray_morph_output.npz \
|
||||
brain.tiff cells3d.tif eagle.png \
|
||||
"${cache_dir}/" || die
|
||||
cp Normal_Epidermis_and_Dermis_with_Intradermal_Nevus_10x.JPG "${cache_dir}"/skin.jpg || die
|
||||
cp pivchallenge/B/B001_1.tif "${cache_dir}"/pivchallenge-B-B001_1.tif || die
|
||||
cp pivchallenge/B/B001_2.tif "${cache_dir}"/pivchallenge-B-B001_2.tif || die
|
||||
cp kidney-tissue-fluorescence.tif "${cache_dir}"/kidney.tif || die
|
||||
cp lily-of-the-valley-fluorescence.tif "${cache_dir}"/lily.tif || die
|
||||
cp astronaut_rl.npy "${cache_dir}/../restoration/" || die
|
||||
popd > /dev/null || die
|
||||
|
||||
distutils-r1_src_test
|
||||
}
|
||||
|
||||
python_test() {
|
||||
local EPYTEST_DESELECT=(
|
||||
# tests for downloading all data files, including these not needed
|
||||
# by any actual tests
|
||||
tests/skimage/data/test_data.py::test_download_all_with_pooch
|
||||
)
|
||||
|
||||
epytest
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
optfeature "FITS io capability" dev-python/astropy
|
||||
optfeature "GTK" dev-python/pygtk
|
||||
optfeature "io plugin providing most standard formats" dev-python/imread
|
||||
optfeature "plotting" dev-python/matplotlib
|
||||
optfeature "wavelet transformations" dev-python/pywavelets
|
||||
optfeature "io plugin providing a wide variety of formats, including specialized formats using in medical imaging." dev-python/simpleitk
|
||||
}
|
||||
Loading…
x
Reference in New Issue
Block a user