From f19f18d32bd3f01024d1d1e4e7760114ef79952d Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Fri, 10 Oct 2025 13:37:40 +0200
Subject: [PATCH] kde-frameworks/kidletime: 6.19.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 kde-frameworks/kidletime/Manifest             |  1 +
 .../kidletime/kidletime-6.19.0.ebuild         | 58 +++++++++++++++++++
 2 files changed, 59 insertions(+)
 create mode 100644 kde-frameworks/kidletime/kidletime-6.19.0.ebuild

diff --git a/kde-frameworks/kidletime/Manifest b/kde-frameworks/kidletime/Manifest
index 01cc153760325..58234d26c740c 100644
--- a/kde-frameworks/kidletime/Manifest
+++ b/kde-frameworks/kidletime/Manifest
@@ -1,2 +1,3 @@
 DIST kidletime-6.16.0.tar.xz 30792 BLAKE2B e48df84c108092cd0aa7e7a1d4a03a1088254ab705887caeeb13ad1fc794a29f84a27695ce10c7bc6e999e3c1c1ec0f19cafd22658b8f05a4b4226501c66c319 SHA512 f7070626a066d5777704239401d6f5b8c0264ea2ba190f5aa34a1cc33c5452d2ab3d88a07c2d417995e26854b97cea9c954f42a48598326bfece071860bc6f3a
 DIST kidletime-6.18.0.tar.xz 30808 BLAKE2B e902f044c53c1c90ac365040a6d3119f11b8db3a65f3abaf01c018beb05d026909e8aab5b749fc8090591089404e82d3fdf11286525392a77171e3a7ae99d228 SHA512 9ff90f2cb5546fd431a3aaa8209a61fe52fa7de9ee8ac935b7c3d8078781279c0c5d4550d79f035d878eace9e136b7a48dd456504f4dba6c8ded3116180973e2
+DIST kidletime-6.19.0.tar.xz 30816 BLAKE2B 82af2045e9c6fbdd4ccdc81284b8aa46fd692424ca36373a6475e244b54c60aaf0a88dd39e145d95ad18282ad4ef5d0d33997487b927d0bccb69629f5a48e4ce SHA512 33bb975a7d648bf6925dc384692f5816d937a9513c1219142bb4a76ba84a96b287a921e41e3dcb98d16671a76db6e009a78f9786855cd8b0bc44a130bc9c9018
diff --git a/kde-frameworks/kidletime/kidletime-6.19.0.ebuild b/kde-frameworks/kidletime/kidletime-6.19.0.ebuild
new file mode 100644
index 0000000000000..a027b39ea5088
--- /dev/null
+++ b/kde-frameworks/kidletime/kidletime-6.19.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="false"
+QTMIN=6.7.2
+inherit ecm frameworks.kde.org
+
+DESCRIPTION="Framework for detection and notification of device idle time"
+
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="wayland X xscreensaver"
+
+REQUIRED_USE="xscreensaver? ( X )"
+
+RDEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[gui]
+	wayland? (
+		dev-libs/wayland
+		>=dev-qt/qtbase-${QTMIN}:6=[wayland]
+	)
+	X? (
+		x11-libs/libX11
+		x11-libs/libxcb
+		x11-libs/libXext
+	)
+	xscreensaver? (
+		>=dev-qt/qtbase-${QTMIN}:6[dbus]
+		x11-libs/libXScrnSaver
+	)
+"
+DEPEND="${RDEPEND}
+	wayland? (
+		>=dev-libs/plasma-wayland-protocols-1.11.1
+		>=dev-libs/wayland-protocols-1.27:0
+	)
+"
+RDEPEND+=" wayland? ( || ( >=dev-qt/qtbase-6.10:6[wayland] <dev-qt/qtwayland-6.10:6 ) )"
+BDEPEND="wayland? ( >=dev-qt/qtbase-${QTMIN}:6[wayland] )"
+BDEPEND+=" wayland? ( || ( >=dev-qt/qtbase-6.10:6[wayland] <dev-qt/qtwayland-6.10:6 ) )"
+
+src_prepare() {
+	ecm_src_prepare
+	if ! use xscreensaver; then
+		sed -i -e "s/\${X11_Xscreensaver_FOUND}/0/" CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_WAYLAND=$(usex wayland)
+		-DWITH_X11=$(usex X)
+	)
+
+	ecm_src_configure
+}