diff --git a/app-accessibility/at-spi2-core/Manifest b/app-accessibility/at-spi2-core/Manifest
index 5aa884114185b..dca7a567f7310 100644
--- a/app-accessibility/at-spi2-core/Manifest
+++ b/app-accessibility/at-spi2-core/Manifest
@@ -1,2 +1,3 @@
 DIST at-spi2-core-2.58.6.tar.xz 589008 BLAKE2B 5940283d8c1c0ee819df48f66e3ad50a1e7ed2f3ad8ef5daa0dd2753da2e2f0ddfc9b75fd420309bfd1633b7fca72eeec3206671a55c3ac39bdf2ba80958e895 SHA512 4b26c4bac5ae99596fbde39f5fdce91fc3f47bc033f37be3ae354f0bb3c44ffeaeaf9b75e43c2fdc715aaa24536f44a353a4e03ccaf45c69d618d99f621a3c92
+DIST at-spi2-core-2.58.7.tar.xz 589488 BLAKE2B 6980d0f75427c2b3e8a0bf509a1a4789f7061d3d22be963711aa033f9a868bdcff597a59ebf6295edcbd674ea29a289acc12b533b7c220b4b160f31418e5a97b SHA512 45275d1fe1f3bfd82862570959e481ce7ceb8923c414e899268adff23652c476610e820019c18239efc5b08aab0763adca083cba8281ef31326384adcc08f4fd
 DIST at-spi2-core-2.60.5.tar.xz 599736 BLAKE2B 94ad495d97b3c43410a2720e341fd90b91b5b33623b2b07abe849e72af874426fd50e92e75e8aecc16f3e5ae7463fa57f3654ca6f5f9293996849a77a7c0e526 SHA512 175811b9ca918908583699ca83e8ec8ec758581da58969e7c2058b3a0ab11179c5361bec035c2a80dbfa77bd10051b1cc947c8851258fac1cb0d8547a4f75342
diff --git a/app-accessibility/at-spi2-core/at-spi2-core-2.58.7.ebuild b/app-accessibility/at-spi2-core/at-spi2-core-2.58.7.ebuild
new file mode 100644
index 0000000000000..ce0a0acf7a5b1
--- /dev/null
+++ b/app-accessibility/at-spi2-core/at-spi2-core-2.58.7.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit gnome.org meson-multilib python-r1 systemd virtualx xdg
+
+DESCRIPTION="D-Bus accessibility specifications and registration daemon"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/at-spi2-core"
+
+LICENSE="LGPL-2.1+"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+IUSE="X dbus-broker gtk-doc +introspection systemd"
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	dbus-broker? ( systemd )
+	gtk-doc? ( X )
+"
+
+DEPEND="
+	>=sys-apps/dbus-1.5[${MULTILIB_USEDEP}]
+	>=dev-libs/glib-2.67.4:2[${MULTILIB_USEDEP}]
+	>=dev-libs/libxml2-2.9.1:2=[${MULTILIB_USEDEP}]
+	introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2:= )
+	systemd? ( sys-apps/systemd[${MULTILIB_USEDEP}] )
+	X? (
+		x11-libs/libX11[${MULTILIB_USEDEP}]
+		x11-libs/libXtst[${MULTILIB_USEDEP}]
+		x11-libs/libXi[${MULTILIB_USEDEP}]
+	)
+
+	!<dev-libs/atk-2.46.0
+"
+RDEPEND="${DEPEND}
+	dbus-broker? ( sys-apps/dbus-broker )
+	${PYTHON_DEPS}
+"
+BDEPEND="
+	dev-util/glib-utils
+	gtk-doc? (
+		dev-python/sphinx
+		dev-util/gdbus-codegen
+		>=dev-util/gi-docgen-2021.1
+	)
+	${PYTHON_DEPS}
+	test? ( dev-python/pygobject[${PYTHON_USEDEP}] )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+multilib_src_configure() {
+	python_setup
+
+	local emesonargs=(
+		-Ddefault_bus=$(usex dbus-broker dbus-broker dbus-daemon)
+		$(meson_use systemd use_systemd)
+		-Dgtk2_atk_adaptor=true
+		-Dsystemd_user_dir="$(systemd_get_userunitdir)"
+		$(meson_native_use_bool gtk-doc docs)
+		$(meson_native_use_feature introspection)
+		$(meson_feature X x11)
+		-Datk_only=false
+		-Dpython="${EPYTHON}"
+	)
+	meson_src_configure
+}
+
+multilib_src_test() {
+	# Avoid locales using commas as decimal separators and breaking some
+	# tests
+	LC_ALL=C.UTF-8 virtx dbus-run-session meson test -C "${BUILD_DIR}" --print-errorlogs || die
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	python_optimize
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/{libatspi,atk} || die
+		mv "${ED}"/usr/share/doc/libatspi "${ED}"/usr/share/gtk-doc/libatspi/html || die
+		mv "${ED}"/usr/share/doc/atk "${ED}"/usr/share/gtk-doc/atk/html || die
+	fi
+}