dev-java/icedtea-web: Version bump to 1.6.2

Package-Manager: portage-2.3.0_rc1

dev-java/icedtea-web/Manifest

@@ -1 +1,2 @@
 DIST icedtea-web-1.6.1.tar.gz 1776222 SHA256 a9b46ab6c9dc303c89651143596bc5abea29242b9bdcabdd2dab7c606592c920 SHA512 dae39818f74a098289acd0736d27c2e68b10b603a3fb0a180cf4b6444345cbe71ab1ba77dfb198f053f9567bb18aa96de09049c3b595b3d292d142a7ae7d3ef9 WHIRLPOOL 96826d17daee16dfa99f6439678cc509c94556955839b7e8bc43c1993ee04740f35b0547d56649bb9f7a625b5b2515be9d173b642ccb15cb1dead83a03586a6e
+DIST icedtea-web-1.6.2.tar.gz 1824557 SHA256 ce67034096d6b960e2b6cfb5c41a7bd6b30eb2ec7f13bf3ecdb477ff6ce69300 SHA512 32c9618a575bf05d3fbe5fec3f8429d55036acde70bf7ccf40b59e14eba775d1f561640acbf673b1737a8c5c3a8eadb74e8f1bef525cfa6060e3f1968d45b3f7 WHIRLPOOL 623a8ea5d5f00aa5e323c4f2de4617a4809149a25f3fbcfbbed76b4a5ecd452c372420dcffd2ad303f815c89168d8820d2997d286e0cc3360054a2c28732b603

dev-java/icedtea-web/icedtea-web-1.6.2.ebuild

@@ -0,0 +1,87 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+README_GENTOO_SUFFIX="-r1"
+
+inherit autotools eutils multilib readme.gentoo-r1 java-pkg-2 xdg-utils
+
+DESCRIPTION="FOSS Java browser plugin and Web Start implementation"
+HOMEPAGE="http://icedtea.classpath.org"
+SRC_URI="http://icedtea.classpath.org/download/source/${P}.tar.gz"
+LICENSE="GPL-2 GPL-2-with-linking-exception LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc64 ~x86"
+IUSE="doc javascript nsplugin tagsoup test"
+RESTRICT="test"
+
+CDEPEND="javascript? ( dev-java/rhino:1.6 )
+	nsplugin? ( >=dev-libs/glib-2.16:2= )
+	tagsoup? ( dev-java/tagsoup:0 )"
+
+DEPEND="${CDEPEND}
+	app-arch/zip
+	>=virtual/jdk-1.7
+	virtual/pkgconfig
+	nsplugin? ( net-misc/npapi-sdk )
+	test? (	>=dev-java/junit-4.8:4 )"
+
+RDEPEND="${CDEPEND}
+	>=app-eselect/eselect-java-0.2.0
+	>=virtual/jre-1.7
+	nsplugin? (
+		!dev-java/oracle-jdk-bin[nsplugin]
+		!dev-java/oracle-jre-bin[nsplugin]
+	)"
+
+src_prepare() {
+	# http://icedtea.classpath.org/bugzilla/show_bug.cgi?id=2855
+	epatch "${FILESDIR}"/${PN}-1.6-{launchers,respect-ldflags,unused-libs}.patch
+
+	if java-pkg_is-vm-version-ge "1.8" ; then
+		sed -i 's/JAVADOC_OPTS=/\0-Xdoclint:none /g' Makefile.am || die
+	fi
+
+	eautoreconf
+}
+
+src_configure() {
+	local tagsoup
+	use tagsoup && tagsoup="$(java-pkg_getjars tagsoup)"
+
+	local config=(
+		# Rename javaws to itweb-javaws as eselect java-vm manages
+		# javaws to prevent a clash with Oracle's implementation.
+		--program-transform-name='s/^javaws$/itweb-javaws/'
+		--libdir="${EPREFIX}"/usr/$(get_libdir)/nsbrowser/plugins
+		--with-java="${EPREFIX}"/usr/bin/java
+		--with-jdk-home="${JAVA_HOME}"
+		$(use_enable doc docs)
+		$(use_enable nsplugin plugin)
+		$(use_with javascript rhino)
+		$(use_with tagsoup tagsoup "${tagsoup}")
+	)
+
+	# See bug #573060.
+	xdg_environment_reset
+
+	# Rely on the --with-jdk-home option given above.
+	unset JAVA_HOME JDK_HOME CLASSPATH JAVAC JAVACFLAGS
+
+	econf "${config[@]}"
+}
+
+src_compile() {
+	default
+}
+
+src_install() {
+	default
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+}