dev-python/flask-whooshalchemy: Bump to 0.8

dev-python/flask-whooshalchemy/Manifest

@@ -1 +1,2 @@
 DIST Flask-WhooshAlchemy-0.56.tar.gz 8528 SHA256 8320ba75040bd37c2810d5ab9a4bd9f3ccadebbef93c805fe0578403f8785baa SHA512 acf7607ad909382bbf3016467cd8e402c98b4618a5822ba6097671becba43f1cac48f6415ce967c4f85c71b71fdafd30c36e5b65e9fc99500c0aad83ea1c650c WHIRLPOOL c08ae0add692379cb1571ff957b4b45447d350c770ad64dde3a5592cbf1b704ee1466f740bc8d6b82750a962695424588717af197e0859a96a28669a935b5e40
+DIST Flask-WhooshAlchemy-0.8.tar.gz 8916 SHA256 45bd638d2ded106d955b9924f27f7ee41c48fbdd5a1fd6b2a892180354006d10 SHA512 c8eff47cedd955d8ad758c8441c3f4e715eed77fbe2749d0830130f6c63547ba7d7fbcade635da0be5f03967c1be01ab7a62939a6d2eba28f9a58b1ab83469a6 WHIRLPOOL 909363e7d7de96a8206dcffba838c5d1fa8b3c55d498c5b018f31f5b67f086d6c8106c123e878fbb02dfd4a97880b09002cc1f4465cfea7b8f847201b0d11f8f

dev-python/flask-whooshalchemy/flask-whooshalchemy-0.8.ebuild

@@ -0,0 +1,44 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_{4,5}} pypy )
+
+inherit distutils-r1
+
+MY_PN="Flask-WhooshAlchemy"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Whoosh extension to Flask/SQLAlchemy"
+HOMEPAGE="https://github.com/gyllstromk/Flask-WhooshAlchemy https://pypi.python.org/pypi/Flask-WhooshAlchemy"
+SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+# TODO: figure out how to make it happy about the newer whoosh
+# (i.e. if it's broken test or broken package)
+RDEPEND="dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/flask-sqlalchemy[${PYTHON_USEDEP}]
+	dev-python/sqlalchemy[${PYTHON_USEDEP}]
+	dev-python/blinker[${PYTHON_USEDEP}]
+	=dev-python/whoosh-2.6.0[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/flask-testing[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	# unbind dependencies from specific versions
+	sed -i -e 's/==.*$//' requirements.txt || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# esetup.py test -- test module decl is broken
+	"${PYTHON}" test/test_all.py || die "Tests fail with ${EPYTHON}"
+}