dev-python/pbr: Bump to 5.5.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/pbr/Manifest

@@ -1 +1,2 @@
 DIST pbr-5.4.5.tar.gz 120510 BLAKE2B f0f22a25e41820a0848aface6c241e38d8c4500d14ac3c8abf3d3b5f3f2d88680505d43f045589d700e9c07ade1643712274b156832246ca3f2050f44e4cda26 SHA512 b53ca10b7af7e365ff99ecf11942d3f047112d69f7e963716d07bc156077b08d79bb708bb93aae342e5e03c83278507b6990137dc34d0ebc11de53bd57ab3654
+DIST pbr-5.5.0.tar.gz 117967 BLAKE2B cc3f023493150f0687ede07ccadc3abfb4a8dc5e0cdc0f9fd946d3a28fe2cf496683f37f934a5555875b5ac0546a0c0ed99e1bc2f7be53b47ec68d64d27cb78a SHA512 ce187787d5a51700d854790b329274aafd7d4f9e724b1b69b5ea8684cdc58c738274d30fd85bb890671bb77f2c7c88ccb488ea11df7ae9fd0505b4dc29292889

dev-python/pbr/pbr-5.5.0.ebuild

@@ -0,0 +1,72 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python2_7 python3_{6..9} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Inject some useful and sensible default behaviors into setuptools"
+HOMEPAGE="https://github.com/openstack-dev/pbr"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+# git is needed for tests, see https://bugs.launchpad.net/pbr/+bug/1326682 and https://bugs.gentoo.org/show_bug.cgi?id=561038
+# docutils is needed for sphinx exceptions... https://bugs.gentoo.org/show_bug.cgi?id=603848
+# stestr is run as external tool
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			>=dev-python/wheel-0.32.0[${PYTHON_USEDEP}]
+			>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+			>=dev-python/mock-2.0.0[${PYTHON_USEDEP}]
+			>=dev-python/six-1.12.0[${PYTHON_USEDEP}]
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			>=dev-python/testresources-2.0.0[${PYTHON_USEDEP}]
+			>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+			>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+			>=dev-python/virtualenv-20.0.3[${PYTHON_USEDEP}]
+			>=dev-python/stestr-2.1.0
+			dev-vcs/git
+		' -3)
+	)"
+PDEPEND=""
+
+# This normally actually belongs here.
+python_prepare_all() {
+	# TODO: investigate
+	sed -e s':test_console_script_develop:_&:' \
+		-e s':test_console_script_install:_&:' \
+		-i pbr/tests/test_core.py || die
+	# broken on pypy3
+	# https://bugs.launchpad.net/pbr/+bug/1881479
+	sed -e 's:test_generates_c_extensions:_&:' \
+		-i pbr/tests/test_packaging.py || die
+	rm pbr/tests/test_wsgi.py || die "couldn't remove wsgi network tests"
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	if ! python_is_python3; then
+		ewarn "Skipping tests on ${EPYTHON} to unblock circular deps."
+		ewarn "Please run tests manually."
+		return
+	fi
+
+	distutils_install_for_testing
+	local -x PATH=${TEST_DIR}/scripts:${PATH}
+
+	rm -rf .testrepository || die "couldn't remove '.testrepository' under ${EPTYHON}"
+
+	stestr init || die "stestr init failed under ${EPYTHON}"
+	stestr run || die "stestr run failed under ${EPYTHON}"
+}