dev-debug/drgn: add 0.0.32

Signed-off-by: Sam James <sam@gentoo.org>

dev-debug/drgn/Manifest

@@ -1 +1,2 @@
 DIST drgn-0.0.31.tar.gz 1493026 BLAKE2B fe4714a5492e6d7059d699183e36b3cb51f0c52a648e73dfa7e81443ab124b6d06a2b0b2a562c3fe98771e8939f362fc1f1f957a5dbd59664595a26187cf75a9 SHA512 9a851e0968ad660c39ff3b26ff1f478a7622db8ddae0c35b60b2db8bc96f3b53e519e0782c1d57171cf45e02db60701d5958190df18b1a41c283a31feb7fc1d2
+DIST drgn-0.0.32.tar.gz 1531692 BLAKE2B d16e7b54609f74515126c9791518976173e5d6a3c9db8df7a14d6e9dac8a0cd8884390cc19f5bbc766e59b1a28bf042247a4096a5358dd46b4c1355974a52dbc SHA512 9a2eb0f714dacdb7f3e70dd393878c7d3b0a6b1577e7a0a437aa938cec77b489fc5737fe82238d43609a00d7dc17016f72e8bdffa53546bae24660a94004a1dd

dev-debug/drgn/drgn-0.0.32.ebuild

@@ -0,0 +1,68 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit distutils-r1 multiprocessing pypi toolchain-funcs
+
+DESCRIPTION="Programmable debugger"
+HOMEPAGE="
+	https://github.com/osandov/drgn
+	https://pypi.org/project/drgn/
+	https://drgn.readthedocs.io/en/latest/
+"
+
+LICENSE="LGPL-2.1+"
+# Note that as of 0.0.31 at least, the API+ABI of libdrgn is unstable.
+SLOT="0/${PV}"
+KEYWORDS="~amd64"
+IUSE="debuginfod lzma openmp"
+
+DEPEND="
+	>=dev-libs/elfutils-0.165[debuginfod?]
+	dev-libs/libkdumpfile:=
+	lzma? ( app-arch/xz-utils )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	test? ( dev-libs/check )
+"
+
+distutils_enable_tests unittest
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_configure() {
+	tc-export AR CC OBJCOPY OBJDUMP PKG_CONFIG RANLIB STRIP
+
+	cat >> setup.cfg <<-EOF || die
+	[build_ext]
+	parallel = $(makeopts_jobs)
+	EOF
+
+	# setuptools calls autotools (!)
+	export CONFIGURE_FLAGS
+	CONFIGURE_FLAGS="--disable-dependency-tracking --disable-silent-rules"
+	CONFIGURE_FLAGS+=" --with-libkdumpfile"
+	CONFIGURE_FLAGS+=" --enable-libdrgn"
+	CONFIGURE_FLAGS+=" --enable-python-extension"
+	CONFIGURE_FLAGS+=" --disable-dlopen-debuginfod"
+	CONFIGURE_FLAGS+=" $(use_with debuginfod)"
+	CONFIGURE_FLAGS+=" $(use_with lzma)"
+	CONFIGURE_FLAGS+=" $(use_enable openmp)"
+	CONFIGURE_FLAGS+=" --build=${CBUILD}"
+	CONFIGURE_FLAGS+=" --host=${CHOST}"
+	CONFIGURE_FLAGS+=" --target=${CTARGET}"
+	distutils-r1_src_configure
+}

dev-debug/drgn/metadata.xml

@@ -11,5 +11,6 @@
 	</upstream>
 	<use>
 		<flag name="debuginfod">Enable debuginfod support</flag>
+		<flag name="lzma">Support XZ-compressed debug information (MiniDebugInfo).</flag>
 	</use>
 </pkgmetadata>